KRL code to save robot Positions timestamped in a text file. (KRC4)

what you are looking for is documented in CREAD/CWRITE manual (use latest version of manual, early version had errors).
bunch of examples (and some issues) have been discussed.

here is some code to read, writing is very much the same...
https://www.robot-forum.com/ro…cwrite/msg88863/#msg88863

There's been a few forum threads discussing this as well -- use the Search function and look for 'fopen', 'fread', 'fwrite', etc.

no problem, glad I could help...

just start timer and use ms from it.

Hi all, currently testing on:

KSS 8.6.6

KR 10 R1100-2

I'm attempting something similar as the above. Attempting to get the workflow in place before it becomes more difficult, but I have a sub file recording the XYZABC of the robot and a timer that is written to a text file with CWRITE. It all seems to work well, except that the timer variable will increase sporadically (maybe when the timer variable is identical to the previous);

The Sub:

DECL CHAR CURRENT[200]
DECL STATE_T S
DECL MODUS_T M
DECL IN OFS
decl bool ran
decl int handle
;ENDFOLD (USER DECL)
;ENDFOLD (DECLARATIONS)
;FOLD INI
;FOLD USER INIT
; Please insert user defined initialization commands
OFS = 0
ran = false
handle = 0


; open file
CWRITE($FCT_CALL,s,m,"krl_fopen","spline_log.txt","a", handle)


;ENDFOLD (USER INIT)
;ENDFOLD (INI)




LOOP
;FOLD USER PLC
;Make your modifications here
;IF ($TIMER[63] > UPDATETIME) THEN


IF RECORD THEN
ran = true
ofs = 0
SWRITE(CURRENT[], S, OFS, "%.4f, %.4f, %.4f, %.4f, %.4f, %.4f, %i", $POS_ACT.X, $POS_ACT.Y, $POS_ACT.Z, $POS_ACT.A, $POS_ACT.B, $POS_ACT.C, $TIMER[8])
M = #SYNC
; write data
CWRITE($FCT_CALL,s,m,"krl_fwriteln", handle, CURRENT[])


ENDIF


IF NOT RECORD AND RAN THEN
; close file
CWRITE($FCT_CALL, s,m,"krl_fclose", handle)
wait sec 0
ran = false
ENDIF


;ENDFOLD (USER PLC)
ENDLOOP


;FOLD ;%{H};
END
;ENDFOLD
;FOLD USER SUBROUTINE
;Integrate your user defined subroutines


;ENDFOLD (USER SUBROUTINE)

the KRL is very simple:

;FOLD LIN SPEED IS 0.25 m/sec, INTERPOLATION SETTINGS IN FOLD
$VEL.CP=0.25
$ADVANCE=3
;ENDFOLD


PTP {X 10, Y -10, Z 0, A 0, B 90, C 0, E1 0, E2 0, E3 0, E4 0, S 'B 110'} C_PTP
LIN {X 10, Y -10, Z 0, A 0, B 90, C 0, E1 0, E2 0, E3 0, E4 0} C_DIS
SPLINE
SPL {X 290, Y -110, Z 0, A 0, B 90, C 0, E1 0, E2 0, E3 0, E4 0} WITH $ORI_TYPE = #VAR
SPL {X 10, Y -210, Z 0, A 0, B 90, C 0, E1 0, E2 0, E3 0, E4 0} WITH $ORI_TYPE = #VAR
SPL {X 290, Y -310, Z 0, A 0, B 90, C 0, E1 0, E2 0, E3 0, E4 0} WITH $ORI_TYPE = #VAR
SPL {X 10, Y -410, Z 0, A 0, B 90, C 0, E1 0, E2 0, E3 0, E4 0} WITH $ORI_TYPE = #VAR
ENDSPLINE
PTP {A1 5, A2 -90, A3 100, A4 5, A5 10, A6 -5, E1 0, E2 0, E3 0, E4 0} C_PTP


END

Any ideas what's causing the timer to add additional numbers. The code ends at 5232ms by the timer, but the last recorded timer variable is 5232066..?

how does the data look like if you hide the last digit in marked range?

also notice that this is the last digit from previous line...

there are two problems here:

1. you are not clearing string before you write to it. this is the root problem. KRL does not have actual STRING data type. character array is used as a crutch... that means there are some side effects including one that rest of the string is not erased when shorter value is written.

DECL CHAR NAME[10]

NAME[]="PETER PAN" ; now name is 'PETER PAN'

NAME[]="BOB" ; now name is 'BOBER PAN'

2. you need to learn to debug and not draw wrong conclusions when observing program behavior. when something unexpected happens you should devise test to see what causes the problem. step through code, add buffer to save copy of values, swap the order of elements etc. it is NOT the timer that has "jumpy value", it is the char array that was not cleared. if you tried one of mentioned things you would see that right away.

to clear string you can use function StrClear(), or use loop to reset each character.

one form of workaround could also be to use fixed width output (your string length changed because of minus sign once it disappeared when value became positive). advantage here is that output is easier to read (by humans) but file will be larger.

... or simply add several space characters at the end of the format string. this will just make the output file larger without but columns would continue to shift based on sign. this is probably why you put timer in the last column.

The various Logxxxx functions in this module may be a useful example.

hmmm... looks suspiciously similar to many of my functions...

even names, order of parameter etc are quite close.

i was rather surprised to see string to/from I/O, i was pretty sure that nobody else would go for it but i guess i was wrong. mine has optional limit so one can make sure that too long strings do not read/write to something out of range.

Quote from panic mode

hmmm... looks suspiciously similar to many of my functions...

Great minds think alike?

At this remove, it's hard to remember which functions I created, and which I collected from various sources. Pretty sure the random-number generator, for one, is based heavily on your example.

Yeah, the string-over-IO function only got developed to a certain point, then stopped, b/c we ended up needing to move so much string data that it would take a couple minutes, even using ridiculous amounts of I/O and assuming 24ms for each block transfer. That's when we switched to using EKI, which was more difficult to set up, but worked much better once it was (aside from causing a SYS 14 fault and hard-killing the robot until KUKA eventually fixed that bug in the EKI error counter).

Thanks for the advice guys. Including the strclear() within the loop worked perfectly. I've also removed the issue of duplicates. It was when moving into negative numbers it was adding 1 to 6 characters to the array through the '-' character that I wasn't accounting for.

Python being the language I'm probably most comfortable in, shifting to KRL is always a bit of a shock to the system.

And thanks for the functions, I'll go over them in detail.

I also found it useful to set every value to a fixed number of characters, and always include the +/- symbol. So lists like:

+0001.10

-0022.02

+9999.99

And so on.

Quote from SkyeFire

Great minds think alike?

At this remove, it's hard to remember which functions I created, and which I collected from various sources. Pretty sure the random-number generator, for one, is based heavily on your example.

Yeah, the string-over-IO function only got developed to a certain point, then stopped, b/c we ended up needing to move so much string data that it would take a couple minutes, even using ridiculous amounts of I/O and assuming 24ms for each block transfer. That's when we switched to using EKI, which was more difficult to set up, but worked much better once it was (aside from causing a SYS 14 fault and hard-killing the robot until KUKA eventually fixed that bug in the EKI error counter).

Interestingly, I started with EKI for this project. The data points were 200ms apart, which was too lo-fidelity, so switched to recording locally on the control pc. Pretty sure it wasn't a networking issue, but that I was using the sps.sub to communicate with EKI, but by that stage I was using cwrite.

I'm surprised I can't write $PRO_NAME[] to a line via swrite? I know the variable is write protected, but does that mean I am unable to read it within the submit interpreter.. ?

SWRITE(FILEINFO[], S, OFS, "%c, %i", $PRO_NAME[], $ACT_BASE)

This line with $pro_name included throws the KSS01422 error that fileinfo[] value invalid. So I attempted to create another CHAR array name[] = $pro_name - still no luck. Is this futile?

edit: I also attempted strcopy..

Quote from singline

I'm surprised I can't write $PRO_NAME[] to a line via swrite? I know the variable is write protected, but does that mean I am unable to read it within the submit interpreter.. ?

Code

SWRITE(FILEINFO[], S, OFS, "%c, %i", $PRO_NAME[], $ACT_BASE)

This line with $pro_name included throws the KSS01422 error that fileinfo[] value invalid. So I attempted to create another CHAR array name[] = $pro_name - still no luck. Is this futile?

edit: I also attempted strcopy..

I'm using it all the time in the sps for reading...

Did you tried also $pro_name1[]?

only $PRO_NAME[] depends on setting in $INTERPRETER