Interrupt Issues

RoboticlyChallenged · February 2, 2017 at 11:50 PM

Controller: KRC4
WV: V3.1.8_Build22

I have searched the forum's and followed what I have found here as well as what I could find in the Systems Integrator manual for programming Interrupts.
By what I can see these 2 interrupts should work, but neither is triggered.

We are using a vacuum sensor on $IN[82] and a Prox sensor on $IN[81].
I have tested both of them outside of this program and they both show as working on the teach pendents I/O display.

When I run the below program the Vacuum sensor triggers but it does not start the interrupt. I have manually triggered the Prox sensor to show true by placing an object infront of it and it doesnt trigger its interrupt either

Any help anyone can provide me would be very much appreciated

Code

DEF  AcrylicFramePickup ( )
   ;FOLD INI
      ;FOLD BASISTECH INI
         GLOBAL INTERRUPT DECL 3 WHEN $STOPMESS==TRUE DO IR_STOPM ( )
         INTERRUPT ON 3 
         BAS (#INITMOV,0 )
      ;ENDFOLD (BASISTECH INI)
      ;FOLD USER INI
         ;Make your modifications here
         INTERRUPT DECL 20 WHEN $IN[82] == TRUE DO SheetFound()
         INTERRUPT DECL 21 WHEN $IN[81] == TRUE DO NoSheetFound ()
      ;ENDFOLD (USER INI)
   ;ENDFOLD (INI)
   $ADVANCE = 0
   INTERRUPT ON 20
   INTERRUPT ON 21


   FindSheet ( )
   $BASE = Base_Data[1]
   $Tool = Tool_Data[8]
   SLIN {X -3140, Y 256, Z -350, A -90, B 7.75, C -179.93} WITH $VEL.cp = .1

   HALT

END


DEF FindSheet ()


   ;FOLD SPTP P1 Vel=10 % PDAT1 Tool[8]:VacHead Base[1]:InspectionStation;%{PE}%R 8.3.31,%MKUKATPBASIS,%CSPLINE,%VSPTP_SB,%P 1:SPTP_SB, 2:P1, 3:, 5:10, 7:PDAT1
      SPTP XP1 WITH $VEL_AXIS[1]= SVEL_JOINT( 10), $TOOL= STOOL2( FP1), $BASE= SBASE( FP1.BASE_NO),$IPO_MODE= SIPO_MODE( FP1.IPO_FRAME), $LOAD= SLOAD( FP1.TOOL_NO), $ACC_AXIS[1]= SACC_JOINT( PPDAT1), $GEAR_JERK[1]= SGEAR_JERK( PPDAT1)
   ;ENDFOLD
   $BASE = Base_Data[1]
   $Tool = Tool_Data[8]
   SLIN {X -3140, Y 256, Z -700, A -90, B 7.75, C -179.93} WITH $VEL.cp = .1
   $OUT[49] = TRUE
   $OUT[57] = TRUE
   SLIN {X -3140, Y 256, Z -30, A -90, B 7.75, C -179.93} WITH $VEL.cp = .01
   ;$APO.CVEL = 1
   ;LIN_REL {Z 30} C_VEL
   ;DEF_APO_CVEL = 100



END


DEF SheetFound ()

   DECL INT ClampCount
   ClampCount = 0
   $BASE = Base_Data[1]
   $Tool = Tool_Data[8]


   WAIT SEC 5
   $OUT[17] = TRUE
   LOOP
      IF $IN[33] AND $IN[35] AND $IN[37] AND $IN[39] == TRUE THEN
         RETURN        
      ELSE
         ClampCount = ClampCount + 1
      ENDIF
      IF ClampCount == 10 THEN
         $OUT[49] = FALSE
         $OUT[50] = TRUE
         WAIT SEC 10
         SLIN {X -3140, Y 256, Z 300, A -90, B 7.75, C -179.93} WITH $VEL.cp = .1
         ; NEED TO SEND SIGNAL TO PLC HERE
      ENDIF
   ENDLOOP
   $OUT[17] = FALSE

   WAIT FOR $IN[82] == TRUE
   RESUME




END


DEF NoSheetFound()
   HALT
END

Display More

**panic mode** · February 3, 2017 at 4:56 AM

interrupts are edge triggered

**SkyeFire** · February 3, 2017 at 1:59 PM

Your INTERRUPT ON commands should be in the FindSheet subroutine, not the main routine. Your Interrupt routines need BRAKE commands and INTERRUPT OFFs at the beginning. Your FindSheet routine needs a WAIT FOR TRUE at the end to ensure that the advance pointer does not make it back to the main routine before an interrupt triggers.

Beyond that, you need to ensure that the Inputs experience a False-to-True transition during the search motion.

RoboticlyChallenged · February 3, 2017 at 5:43 PM

Thank you both for the help,

SkyFire, I added in the recommended lines and it worked perfectly. I got confused and didnt realize the Interrupts needed to be started in the first subprogram not the main.

Thank you again

EDIT: So I have done this, and now the interrupts are working, but it is coming out of the interrupt at the same point in the main program which causes the robot to move in the same direction that initially triggered the interrupt.

Code

&ACCESS RVP
&REL 13
DEF  AcrylicFramePickup ( )
   ;FOLD INI
      ;FOLD BASISTECH INI
         GLOBAL INTERRUPT DECL 3 WHEN $STOPMESS==TRUE DO IR_STOPM ( )
         INTERRUPT ON 3 
         BAS (#INITMOV,0 )
      ;ENDFOLD (BASISTECH INI)
      ;FOLD USER INI
         ;Make your modifications here
         INTERRUPT DECL 20 WHEN $IN[82] == TRUE DO SheetFound()
         INTERRUPT DECL 21 WHEN $IN[81] == TRUE DO NoSheetFound ()
      ;ENDFOLD (USER INI)
   ;ENDFOLD (INI)
   $ADVANCE = 0

   FindSheet ()

   INTERRUPT OFF 20
   INTERRUPT OFF 21

   $BASE = Base_Data[1]
   $Tool = Tool_Data[8]
   SLIN {X -3140, Y 300, Z -350, A -90, B 7.75, C -179.93} WITH $VEL.cp = .1

   HALT

END


DEF FindSheet ()

   INTERRUPT ON 20
   INTERRUPT ON 21
   ;FOLD SPTP P1 Vel=10 % PDAT1 Tool[8]:VacHead Base[1]:InspectionStation;%{PE}%R 8.3.31,%MKUKATPBASIS,%CSPLINE,%VSPTP_SB,%P 1:SPTP_SB, 2:P1, 3:, 5:10, 7:PDAT1
      SPTP XP1 WITH $VEL_AXIS[1]= SVEL_JOINT( 10), $TOOL= STOOL2( FP1), $BASE= SBASE( FP1.BASE_NO),$IPO_MODE= SIPO_MODE( FP1.IPO_FRAME), $LOAD= SLOAD( FP1.TOOL_NO), $ACC_AXIS[1]= SACC_JOINT( PPDAT1), $GEAR_JERK[1]= SGEAR_JERK( PPDAT1)
   ;ENDFOLD
   $BASE = Base_Data[1]
   $Tool = Tool_Data[8]
   SPTP {X -3140, Y 256, Z -265, A -90, B 7.75, C -179.93} WITH $VEL.cp = .1
   $OUT[49] = TRUE
   $OUT[57] = TRUE


   SLIN {X -3140, Y 256, Z -30, A -90, B 7.75, C -179.93} WITH $VEL.cp = .005


   WAIT FOR $IN[33] AND $IN[35] AND $IN[37] AND $IN[39] == TRUE
   WAIT SEC 0
   RESUME 
   ;$APO.CVEL = 1
   ;LIN_REL {Z 30} C_VEL
   ;DEF_APO_CVEL = 100



END


DEF SheetFound ()


   INTERRUPT OFF 20

   BRAKE
   ClampCount = 0
   $BASE = Base_Data[1]
   $Tool = Tool_Data[8]


   WAIT SEC 5
   $OUT[17] = TRUE

   LOOP
   WAIT SEC 1
      IF $IN[33] AND $IN[35] AND $IN[37] AND $IN[39] == TRUE THEN
         RETURN        
      ELSE
         ClampCount = ClampCount + 1
      ENDIF
      IF ClampCount == 10 THEN
         $OUT[49] = FALSE
         $OUT[50] = TRUE
         WAIT SEC 10
         SLIN {X -3140, Y 256, Z -300, A -90, B 7.75, C -179.93} WITH $VEL.cp = .01
         ; NEED TO SEND SIGNAL TO PLC HERE
      ENDIF
   ENDLOOP
   $OUT[17] = FALSE

   WAIT FOR $IN[82] == TRUE

   RESUME





END


DEF NoSheetFound()


   BRAKE
   INTERRUPT OFF 20
   INTERRUPT OFF 21
   HALT
END

Display More

After the interrupt sub program has finished it moves back to " SLIN {X -3140, Y 256, Z -30, A -90, B 7.75, C -179.93} WITH $VEL.cp = .005" and keeps trying to make it to (Z -30). This is causing the robot to push the EOT through the material. I am trying to figure out how to get it to start the line after, so it will go back to the AcrylicFramePickup () main program and move away from the found object.

**SkyeFire** · February 3, 2017 at 11:42 PM

Why do you have a RESUME in your search program, and a RETURN in your interrupt routine?

RoboticlyChallenged · February 4, 2017 at 12:00 AM

I honestly slipped up with the RESUME being in there, but the RETURN is there inside an IF statement, inside a loop that I am now dumbly realizing should be an EXIT statement.

Removing that RESUME and changing the RETURN to an EXIT will solve the issue of the interrupt starting back on the FindSheet () line that the interrupt was triggered on?

**SkyeFire** · February 6, 2017 at 3:09 PM

One hopes. The RESUME command in the interrupt routine should cancel any motions active in the search routine, and jump the program pointer back to the level where the interrupt was declared, one line after it left.
Also, you should only have your Interrupts active during the search motion. So if the robot finishes the entire search motion without tripping the interrupts, you should turn the Interrupts off before making your escape motion. Don't wait until you're up in Main.
Hm... if you do all that, and it still tries to execute that Z-30 motion, try placing a WAIT SEC 0 immediately following your search motion command.

Interrupt Issues

Advertising from our partners

How to see your Job Posting (search or recruit) here in Robot-Forum.com