How can
open a 20mm circle at the center outwards
good work
How can
open a 20mm circle at the center outwards
good work
Hi
You can see below procedure. It works with reltool and offset.
Offset mean, it works releated world coordinated system.
RelTool mean, it works with tool coordinated system.
PROC Circle(
bool bRelTool,
robtarget pPosition,
num nRadius_mm,
speeddata vSpeed,
PERS wobjdata obWobj)
IF bRelTool THEN
MoveL RelTool(pPosition,0,0,0\Rx:=0\Ry:=0\Rz:=0),vSpeed,fine,T_Spn\WObj:=obWobj;
MoveL RelTool(pPosition,-nRadius_mm,0,0\Rx:=0\Ry:=0\Rz:=0),vSpeed,fine,T_Spn\WObj:=obWobj;
MoveC RelTool(pPosition,0,-nRadius_mm,0\Rx:=0\Ry:=0\Rz:=0),RelTool(pPosition,nRadius_mm,0,0\Rx:=0\Ry:=0\Rz:=0),vSpeed,z1,T_Spn\WObj:=obWobj;
MoveC RelTool(pPosition,0,nRadius_mm,0\Rx:=0\Ry:=0\Rz:=0),RelTool(pPosition,-nRadius_mm,0,0\Rx:=0\Ry:=0\Rz:=0),vSpeed,z1,T_Spn\WObj:=obWobj;
MoveL RelTool(pPosition,0,0,20\Rx:=0\Ry:=0\Rz:=0),vSpeed,fine,T_Spn\WObj:=obWobj;
ELSE
MoveL pPosition,vSpeed,fine,T_Spn\WObj:=obWobj;
MoveL Offs(pPosition,-nRadius_mm,0,0),vSpeed,fine,T_Spn\WObj:=obWobj;
MoveC Offs(pPosition,0,-nRadius_mm,0),Offs(pPosition,nRadius_mm,0,0),vSpeed,z1,T_Spn\WObj:=obWobj;
MoveC Offs(pPosition,0,nRadius_mm,0),Offs(pPosition,-nRadius_mm,0,0),vSpeed,z1,T_Spn\WObj:=obWobj;
MoveL Offs(pPosition,-nRadius_mm,0,20),vSpeed,fine,T_Spn\WObj:=obWobj;
ENDIF
ENDPROC
That looks ( it is! ) like an old ABBIR/ KMT piece of rapid! You can see it is based on our M94 tcp as the reltool is in y and z.
You must know the tool coordinate directions before writing the reltool rapid.
Ulkers - Have you used our waterjet systems in the past?
!***************************************************************************
!Procedure: CircleHole without trigg function
!***************************************************************************
!***************************************************************************
!ABB I-R Robotized Waterjet AB (SERWJ)
!
!Version:1.0
!Date:961108
!Procedure:Circle
!Parameters:
!Description:The routine makes a circle, relative tool or, relative
! workobject due to the choise of bRelTool (boolean)
!
!History:This routine will replace the older routines Circle and
!CirRelTool
!***************************************************************************
PROC Circle(
bool bRelTool,
robtarget pPosition,
num nRadius_mm,
speeddata vSpeed,
PERS wobjdata obWobj)
IF bRelTool THEN
!Circleprogram with RELTOOL
!The cut will be 90deg towards the surface
!Kreisprogramm mit RELTOOL-funktion
!Der Kreis wird 90grad zu HD-rohr geschnitten
!Programme cercle a RELTOOL
!Decoupe perpeniculaire a la surface
!Copyright ABB I-R,1995-01-11
MoveL RelTool(pPosition,0,0,0\Rx:=0\Ry:=0\Rz:=0),vStart,fine,TCP1\WObj:=obWobj;
Set doHpWater;
MoveC RelTool(pPosition,0,nRadius_mm/2,nRadius_mm/2\Rx:=0\Ry:=0\Rz:=0),RelTool(pPosition,0,0,nRadius_mm\Rx:=0\Ry:=0\Rz:=0),vSpeed,z1,TCP1\WObj:=obWobj;
MoveC RelTool(pPosition,0,-nRadius_mm,0\Rx:=0\Ry:=0\Rz:=0),RelTool(pPosition,0,0,-nRadius_mm\Rx:=0\Ry:=0\Rz:=0),vSpeed,z1,TCP1\WObj:=obWobj;
MoveC RelTool(pPosition,0,nRadius_mm,0\Rx:=0\Ry:=0\Rz:=0),RelTool(pPosition,0,0,nRadius_mm\Rx:=0\Ry:=0\Rz:=0),vSpeed,z1,TCP1\WObj:=obWobj;
MoveC RelTool(pPosition,0,-nRadius_mm/2,nRadius_mm/2\Rx:=0\Ry:=0\Rz:=0),RelTool(pPosition,0,0,0\Rx:=0\Ry:=0\Rz:=0),vSpeed,fine,TCP1\WObj:=obWobj;
Reset doHpWater;
WaitTime nTimeCl;
ELSE
!Circleprogram
!The cut will be 90deg towards active WorkObject
!Kreisprogramm
!Der Kreis wird 90grad zu aktive WorkObject geschnitten
!Decoupe perpeniculaire a la WorkObject
MoveL pPosition,vStart,fine,TCP1\WObj:=obWobj;
Set doHpWater;
MoveC Offs(pPosition,-nRadius_mm/2,nRadius_mm/2,0),Offs(pPosition,-nRadius_mm,0,0),vSpeed,z1,TCP1\WObj:=obWobj;
MoveC Offs(pPosition,0,-nRadius_mm,0),Offs(pPosition,nRadius_mm,0,0),vSpeed,z1,TCP1\WObj:=obWobj;
MoveC Offs(pPosition,0,nRadius_mm,0),Offs(pPosition,-nRadius_mm,0,0),vSpeed,z1,TCP1\WObj:=obWobj;
MoveC Offs(pPosition,-nRadius_mm/2,-nRadius_mm/2,0),Offs(pPosition,0,0,0),vSpeed,fine,TCP1\WObj:=obWobj;
Reset doHpWater;
WaitTime nTimeCl;
ENDIF
ENDPROC
Offset mean, it works releated world coordinated system.
I think, that it actually works related to selected WObj Coordinate System.