How safe is it to "split" a motion to an axis-specified position?

It is possible to swing single axis as a time... You cannot have variables in the curly braces yes... but you can do:

DECL E6AXIS HOLDER
HOLDER=$AXIS_ACT ;WHERE EVER YOU ARE, POPULATE THIS VARIABLE
HOLDER.A1 = VARIABLE
PTP HOLDER 
...

This should drive a single axis. The trick between mine and yours is using $AXIS_ACT.

I see. I don't have a lot of context, but you can have A2 ... A6 pre populated, and only have A1 based on a variable like:

DECL E6AXIS HOLDER
;HOLDER=$AXIS_ACT ;WHERE EVER YOU ARE, POPULATE THIS VARIABLE
HOLDER.A1 = VARIABLE
HOLDER.A2 = 2
HOLDER.A3 = 3
HOLDER.A4 = 4
HOLDER.A5 = 5
HOLDER.A6 = 6
PTP HOLDER 
...

Don't understand the task.

- you have one special position where you want to avoid collision? So why not using a fix position.

- you have many positions where you want to avoid collision, how is it possible that on every position you have the same strategy to avoid collision?

Even if I don't understand the problem, may be it could be a solution to calculate the position backwards from target.

Quote from mudanda

While this works, I was just wondering if it is "safe" to do so.

Yes, this works and is completely safe, as far as I know. For E6AXIS and E6POS points, any axes that are left undefined simply result in those axes being kept in their previous position.

So, DECL E6AXIS PSafe={A1 90}, then using PTP PSafe, will result in A1 moving to 90deg while A2-A5 remain unmoved.

Now, this does have some potential issues. For example, if the previous move is approximated, then A2-A5 will complete their motion over the course of the approximation arc. So this could be unsafe to use in conditions where the motion is very close to collision and could be executed from multiple different starting directions. Avoiding approximation, or using smaller approximation radii, would be wise in that case.

DECLing PSafe (don't use P00, that's a reserved keyword) in a DAT file could be dangerous, if someone were to edit it. Also, using PSafe in an Inline Form would be VERY dangerous, as anyone using TouchUp on that form would rewrite all values of PSafe to the current position. So it's probably safer to DECL PSafe inside the active routine, and then assign a value only to A1. This way, unless someone edits the .SRC file, it should avoid the risks of someone tampering with it not knowing what they're doing.

In a first step I would initialize with the actual position (axes specific - like PSafe as mentioned above).
In the second step just change the axis (as SkyFire mentioned) like PSave={A1 90} and so on

I do not like phrases like

Quote from SkyeFire

any axes that are left undefined

(the complete movement is undefined)

Like (I do not have a system for testing):

DECL E6AXIS PSafe=$ACT_AXIS
PTP PSafe={A1 90}

something like that - all axes are initialized and with the PTP you only change the axis as requested

Quote from mudanda

Is it possible to "clear" the content of tempAxis to use it again, in the same way but using different coordinates?

yes it is possible...

put it into a subroutine (or function). this way every time that routine is called, runtime variable in that routine is not initialized. you can then selectively initialize rest.

DEF SafePos_A1(a1_value:in)
   DECL REAL a1_value
   DECL AXIS temp
   temp.A1 = a1_value
   PTP temp
END

or

DEFFCT AXIS SafePos(A1:in,A2:in,A3:in,A4:in,A5:in,A6:in)
  DECL REAL A1,A2,A3,A4,A5,A6
  DECL AXIS temp
  If VarState("A1")==#INITIALIZED THEN
     temp.A1=A1
  endif
  If VarState("A2")==#INITIALIZED THEN
     temp.A2=A2
  endif
  If VarState("A3")==#INITIALIZED THEN
     temp.A3=A3
  endif
  If VarState("A4")==#INITIALIZED THEN
     temp.A4=A4
  endif
  If VarState("A5")==#INITIALIZED THEN
     temp.A5=A5
  endif
  If VarState("A6")==#INITIALIZED THEN
     temp.A6=A6
  endif
  return temp
ENDFCT

and to move to {A1 25, A4 75, A6 -10} call it like this.

Simply leave unwanted axis empty, but - do not forget the commas. they determine which value lands where.

PTP SafePos(24,,,75,,-10) ; only enter values for A1, A4 and A6

and with this, you can also use variables...

PTP SafePos( ,,,,,$OV_JOG) ; turn A6 to whatever $OV_JOG value is... (or whatever variable you want...)

you can skip commas if nothing else is entered after them

PTP SafePos( ,,90) ; turn A3 to 90 deg, A3 is last value provided so commas after it are not needed. but A1 and A2 are skipped so commas are needed there

panic mode

You have a system available (?).

Write a simple program and declare DECL AXIS temp and using variable to show the result - please, just to learn - thanx in advance

I am not sure what would be a convincing argument... i guess one would have to try it an see it... which is what i have done many moons ago.

KRL does NOT un-initialize variables... ever...!

When variables are declared they are always un-initialized ... but ... as soon as SOMETHING is assigned to it, that variable IS initialized.. and it STAYS initialized... for the REST OF THE LIFE of that variable. only if variable is a structure, it is possible to un-initialize some elements of it (but not all).

1. consider variable declared in DAT file of program module called PANIC (which contains files PANIC.SRC and PANIC.DAT)

DECL AXIS A_DAT

right now that value is not initialized.

selecting program module PANIC, shows PANIC.SRC in the HMI.

if one assigns value to that variable somehow (by program line in that SRC file or using variable monitor), variable becomes initialized.

A_DAT = {A4 75}

note that A_DAT is an axis so it has 6 elements (A1 - A6) but at this moment only element A4 is initialized.

VarSTate("A_DAT") returns TRUE, (as long as ANY part of structure is initialized, result is true)

VarState("A_DAT.A5") returns false, because now we are specifically checking element A5 of A_DAT

...

deselecting program hides the program module and blocks access to this variable. one can select another programs and check other variables... then come back and select PANIC.SRC and voila.. that variable value is still there... because memory for it is resevered "permanently" (until reboot). therefore A_DAT.A4 still has value. and A_DAT will remain initialized no matter what... until end of life of that variable. deselecting program module did not clear it. but rebooting will clear it...

consequence of this is that you cannot recover memory from variables that are declared in DAT files... so by sleeting bunch of programs that have lots of things declared in their DAT file, your controller can run out of memory and only way to purge it is to reboot...

2. consider variable declared in a SRC file such as:

DECL AXIS A_SRC

this variable is also not initialized. but.. it can be initialized just like the previous one. the difference is that this variable is a runtime variable. memory assigned to this variable is returned to system as soon as this routine ends. so one can continuously create, run, delete program modules... all day long, over and over.. without EVER running out of memory.

3. consider variable declared in DAT file and also INITIALIZED in the DAT file...
DECL REAL PI = 4.0 ; declaration AND initialization in one line only works in DAT files.

as soon as module is compiled and selected that value will be assigned. but... this is still a VARIABLE... so value CAN change...
if you select the program module of DAT file where this is declared, you can change the value, for example by using assignment in the SRC file, or by using variable monitor...
say we make change it to PI = 3.14...
if you go back and check the DAT file, declaration now has been modified so it shows the most recent value:
DECL REAL PI = 3.14

and since this is now part of file, this value is retentive. even after reboot, controller will read this value and PI will be whatever the last value you assigned to it. This is how data points of inline form motions are retained. but.. still there is no way to un-initialize it...

4. consider variable of some type of structure such either of above two examples.
structure is an assembly or collection of values, each represented by own variable (element). KRL considers variable initialized as soon as ANY element of the structure is initialized. and as shown above one can check for initialization of main variable or variable element.

but.. as soon as some element is initialized, the main (structure) variable is initialized and there is no way that i can think of to un-initialize it. you cannot assign value to structure from something that is not initialized. you CAN choose which elements you are assigning and if assigned value is a literal, then it is possible to un-initialize some elements of the structure.. but not all of them.

Example

DECL AXIS W

W = {A4 100} ; W and W.A4 are initialized, but not the other elements.
W = {A2 -90} ; W and W.A2 are initialized, but not the other elements. note that W.A4 element is no longer initialized but that is only possible because SOME part of W is still initialized (in this case that is W.A2)

W.A1 = 45 ; now W.A1=34, W.A2=-90, other elements are not initialized. using dot operator to access elements one can initialize them directly but not un-initialize.
W = {A4 333} ; now W.A4 is the only element initialized (and so is W) but values of W.A1 and W.A2 are lost, they became un-initialized.

with all this.. it should be clear how previously mentioned function SafePos() works. when called, it creates local variables (runtime) which are of course un-initialized. then selectively, some elements can be assigned value. as long as at least one of the elements has value, function can return entire structure as a result - even if some elements of that results are not initialized... and this result can be either assigned to some variable or used directly in motion instructions as already shown.

using same approach one can for example strip S&T from POS variables.

here is an example of using function result directly in motion instruction

or variable