Motion Stops Between Points

Good morning, I'm programming a KUKA kr 470-2 PA e¡with KR C5 and KSS 8.7.6.

I see stops between points when I trigger some programs. I use trigger when distance = 1 or when path = -200 depending on ptp or lin.

The programs have no INIT. If I activate a signal or have waits I have a Continue on the previous line. I tried to set the conditions of the waits to true with the plc before evaluating them. $APO.CDIS=200 $ADVANCE=3. I activated $STOPNOAPROX to true in automatic and I don't see any change in the flow nor messages.

Few experience programming Kuka but research done, so any advice will be well received. Thanks.

There is no direction nor orientation change, as it is a palletizing application where the robot travels to the access point (axis defined) then it lowers its position changing only z coord (but also axis defined also ptp, where the triggers are thrown and I see the stop : point P_ACCESS_PICK_AXIS ) and if permissions are ok it continues lowering to pick position by changing only z coordinate but since there LIN.

Pick and place program:

DEF PICK_AND_PLACE ()

      ; Interrupts 
      INTERRUPT DECL 1 WHEN $CYCFLAG[1] DO GET_HEIGHT()
      INTERRUPT DECL 3 WHEN $CYCFLAG[3] DO GET_HEIGHT()
      WATCH(#W_OFF,1)
      WATCH(#W_OFF,3)
      SET_LIN_VEL(FAST_VEL)
      $APO.CDIS = CONTOUR       
      
      ; Tool config    
      TOOL(#POS_SPACER_PICK) ; Start the sequence to postion the spacer at target postion and continue executing the program          
   
   ;----------------------------------------------------------------------------------
   ;PICK 
   ; Compute trajectory points
   P_ENT_PICK_CART = Set_Point_Z(P_ACCESS_PICK_CART,PickEntryPointCoordZ)
   P_PICK_CART = Set_Point_Z(P_ACCESS_PICK_CART,PickOffset_Z)
   

   BAS(#BASE,SOURCE_BASE) ;Frame Id of Table 
   PTP P_ACCESS_PICK_AUX_AXIS C_DIS    
   
   ; Check if the spacer its at the requested position ; 28/10/2024 cambiado de acccion directa a trigger 
   TRIGGER WHEN DISTANCE = 1 DELAY = 0 DO TOOL(#CHK_SPACER_POS_OK) PRIO =-1 

   ; Wait for permission to enter 
   TRIGGER WHEN DISTANCE = 1  DELAY = 0 DO ROBOT(#CHK_ACCESS_PERM,SOURCE_BASE) PRIO =-1  
  
   PTP P_ACCESS_PICK_AXIS C_DIS 
   TRIGGER WHEN PATH = 60 ONSTART DELAY = 0 DO ROBOT(#BLOCK_ZONE,SOURCE_BASE) PRIO=-1;

   IF I_Spacer_Test_Mode == TRUE THEN 
      $APO.CDIS = 20
      LIN P_ENT_PICK_CART ; 
      TOOL(#TEST_MODE_SPACER_POS)  
   ENDIF
      
   ;Define the collision sensivity (150% default)
   SET_TQ_VALUES (150,160,160,150,160,150)
   

   SET_LIN_VEL(SLOW_VEL)
   LIN P_PICK_CART  
   SET_LIN_VEL(FAST_VEL)        
   
   TOOL(#CLS) ; Close Tool 
   .
   .
   . (continues but out of scope)

Thanks in advance,

Quote from Fubini

Load data is set correct?

I "guess so" - used values that mechanical department sent to me (mass, cog, intertia..) - I don't know how reliable are they as the LoadDataDetermination was not purchased.

Quote from Hes

Which motions do not approximate? Some motions do not have any approximation assigned to them.

I`m talking about PTP P_ACCESS_PICK_AXIS C_DIS (in line 30 of pick and place program), that stops instead continuing smoothly with LIN P_PICK_CART (in line 44).

Quote from Hes

Btw trigger when path works with both SLIN & SPTP. I did not know trigger when path wotked with legacy ptp motions, maybe this has something to do with the problem you are experiencing?

Trigger When Path on my program is intended to work with the LIN P_PICK_CART line 44.

Quote from Hes

Do you have any mix of new and legacy motions that might be the culprit?

As far as I know, they are not always intended for the same, so there shold be no probelm with using one or other in the same application, nevertheless in that part I don't use any Smotion.

Quote from Hes

Do you absolutely get no messages when running the program? Approximation not possible messages are suppressed in EXT, but show up in T1 & T2

So they were suppressed, as I was executing in EXT. Didn't know about that fact. The program has routines that don't let to execute the application in T1 or T2, I can try to block them temporarly.

Thanks,

Quote from Hes

Try putting a continue before the if block on line 33. Uncertain if set_tq_values on line 40 is possible to do on the fly, i expect it would cause and advance run stop. Can you comment it out to test and verify.

Done both and problem solved! Thanks a lot, I will individualize the actions done to know which was the culprit when the the production stops. Then I will comment on here.

Checked and it was the setting of torque values for the collision detection. SET_TQ_VALUES() causes ARP to stop. As I noticed during this test, the update of that values can only be done when robot stop its motions.