KRC4 controller

Current college course material is focusing on manipulatin of structures... such as programming messages and creating offets by modifying points... and for many people that is enough (or too much). And while Kuka training is great, I wish that basic course (programming1) has $PAL_MODE mentioned and that advanced course (programming2) has geometric operator covered (at least mentioned/demonstrated). Reason is that those topics are common, important and deserve mention so that people graduating the course do not get stumped when facing 5-axis palletiser (trying to do mastering for example) or when deciding how to apply offsets in programs. both of them can be easily covered/demonstrated in short time, without sacrificing moch or impacting existing topics.

geometric operator adds offsets to chosen frame or point.
this can be added before and after point (or both) and it can be extended by cascading more operations.

One thing mentioned in the advanced course is that one can use relative motion to retract in tool direction such as

LIN_REL {X -100} #TOOL

this assumes that tool direction is X+

note that parameter #TOOL is important. if omitted, robot will default to move in base coordinates:

LIN_REL {X -100} #BASE
LIN_REL {X -100}

both above lines are the same.

but...

also consider this:

DECL FRAME Above, Retract
DECL POS StartPos

Above   = {X 0, Y 0, Z 150, A 0, B 0, C 0}
Retract = {X -150, Y 0, Z 0, A 0, B 0, C 0}

$base=base_data[6] ; whatever base
$tool=tool_data[6] ; whatever tool

PTP xHOME      ; this can be inline form too
PTP Above:xP1
LIN xP1        ; this can be inline form too
WAIT SEC 1
LIN Above:xP1
PTP xHOME      ; this can be inline form too

HALT

PTP xHOME      ; this can be inline form too
PTP {A5 45}    
StartPos = $POS_ACT
LIN Above:StartPos
LIN Above:StartPos:Retract
LIN Above:StartPos:Retract:Retract:Retract:Retract
LIN Above:StartPos
LIN StartPos
PTP xHOME      ; this can be inline form too

No. Use:

Lin StartPos:retract

This is offset (retract) in tool coordinates. But you said that you also have an offset (above) in x and y relative to base, this is stored in 'above' so if you want to use offset in base and tool you use:

LIN Above:StartPos:Retract

The #tool command is only applicable on relative motions like lin_rel.

One way to think about the Geometric Operator when used on POS variables is this: anything on the left side of the : is treated as a Base offset, and anything on the right is treated as a Tool offset. There's a lot more complexity that I'm leaving out, but this is a decent approximation to start with.

So, LIN BaseOffset : xP1 : ToolOffset would apply a Base shift to xP1, followed by a Tool offset. In this example, if BaseOffset were {X 0,Y 0,Z 100,A 0,B 0,C 0}, and ToolOffset were {X 0,Y 0,Z 0,A 0,B 0,C 45}, this motion command would place the TCP 100mm above xP1 in $BASE Z, and rotated 45deg around the TCP X axis relative to xP1.

The Geometric Operator always works left-to-right, and each shift adds to the ones before it.

that is correct...

StartPos is initial position...
geometric operation applied before (left side of) that point is in base frame.
geometric operation applied after (right side of) that point is in tool frame.

so line 26 goes to same point that robot is at in line 21.

line 22 moves robot "up" in base frame
line 23 moves "back" in tool frame
and operations can be compounded so adding offset more than once can be used to increase the overall travel.
for example line 24 does just that. endpoint is lifted once in base frame (above) and also moved back 4x the Retract distance in tool direction (tool offset is -600mm in tool X direction).

btw. the motion is still single motion:

LIN Above:StartPos:Retract:Retract:Retract:Retract

is same as

DECL PTP temp
temp=Above:StartPos:Retract:Retract:Retract:Retract
LIN temp

the nice thing of using this way to compute approach/departure points is particularly nice when you want to constrain what user can touchup. the idea is to only use inline form motions on points that permit touchup and have other points calculated. and placing calculation into line with motion instruction is very nice. because you can immediately use any calculated point and see result. this is not how things work when point is calculated in a manner shown in post #1. there result is stored in a variable and to see result of modified reference point, one would need to return to begin of calculation. that requires more attention and understanding how code works (read the code, identify begin of calculation, go to that line, step through several lines...). with geometric operator used the way i have shown, all of this gores away. you just block select the motion you are interested in and do a BCO - that's it... robot will calculate and move to that point in one go....

for example, if vertical approach (palletizing/depalletizing):

LIN Above:xP1; Approach, always calculated
LIN P1 Vel 0.5 m/s .... (this is an inline form)
; gripper action (open/close)
LIN Above:xP1 ; departure, always calculated

or approach/departure in tool direction

LIN xP1:Before; Approach, always calculated
LIN P1 Vel 0.5 m/s .... (this is an inline form)
; gripper action (open/close)
LIN xP1:Before ; departure, always calculated

so after touchup, just select previous line and run to see all changes.