Get Real Time Speed | Kawasaki E-Series Controller

Welcome to the forum..........

With sealing spec robots, they already have commands available to integrate with a dispenser for flow control, bead shaping, purge controls, gun on/off timing with distance to retard or advance flow.

However, not all of it is 100% documented if you use third party dispensers (ie not a fully supplied Kawasaki system).

Attached is a manual referencing flow rate control (D controller, but still applicable for E Series) usually available to supplied sealing spec systems.

Key commands are:

FLOWRATE (System Switch to off for speed control)

SETOUTSIG

SETOUTSPEED

OUTSPEED

The following example code (demonstration of function only) is something I use to demonstrate a simple live speed feedback when moving the robot in teach mode executing it as pc task.

A simple interface panel to display commanded speed, actual speed, and representative integer value provided by signals of the actual speed.

If you cross reference the following commands, with the manual, you'll see how this is achieved.

.INTER_PANEL_D
15,8,"cmd.tcp.spd"," COMMAND","SPEED  MMS",7,2,5,2,-1
17,8,"act.tcp.spd","  ENCODER","SPEED  MMS",7,2,5,2,-1
19,8,"int.tcp.spd","   BITS","OUTPUT VAL",7,2,5,1,-1
.END
.PROGRAM tcp_spd.pc(); TCP SPEED
;=====================================================================
; PC Task to set bits for TCP speed feedback for flow feedback
; Shows Commanded Speed, Actual Encoder Speed and Integer Speed BITS
; Motion steps using LMOVES are more accurate
;=====================================================================
; Set overall parameters for teach speed maximum 250mm/s
; Use BASE or TOOL Interpolation for demonstration
; Adjust Speed levels in aux 0401 to suit
  FLOWRATE OFF;
  SETOUTSIG 2001,8,1; set 8 bits from 2001 (LSB) for TCP speed
  SETOUTSPEED 0,250,10,0.1; max speed here = 255 for bits output
  OUTSPEED; Start speed output
;=====================================================================
again:; Constantly update values on IFP
  cmd.tcp.spd = OUTSPEED(1); Commanded speed
  act.tcp.spd = OUTSPEED(0); Actual speed from encoder
  int.tcp.spd = BITS(2001,8); Integer speed from bits
  TWAIT 0.016;
  GOTO again;
;=====================================================================
.END

Obviously this is not how you would use it in production, however just by having the following integrated into your code prior to laying the bead then the following will produce a BCD integer via the 8 bits representative of the tcp speed (in this case max speed of 255mm/s) which you can plumb into your dispenser (you may need to use a multiplier in the dispenser to further tune it), this is a common method when not using any standard analog feedback options to the dispenser:

  SETOUTSIG 1,8,1 ;    
  SETOUTSPEED 0,bead_spd_rq,10,0.1; 
  OUTSPEED;

Let us know how you get on and hope it helps.............