$CYCFLAG mysterious behaviour

Hes · May 27th 2022

Hi,

I´ve been fiddling around with $CYCFLAG´s lately and I found it very odd that I have a hard time getting them reset.

Originally I was hoping to set a $CYCFLAG from a *.src and later on reset it in an extended submit with $CYCFLAG[X]=FALSE as I understand is the way to reset it.

From the KSS 8.5 system variables documentation I can see that it reads:

"Cyclical evaluation of cyclical flags can be activated by assigning a Boolean

expression in a robot program. Assignment of a Boolean expression

in a submit program does not result in cyclical evaluation."

There is nothing stated about resetting a $CYCFLAG in a submit program so I figured I´d test it.

This did not turn work as intended and I dumbed down the code and tested some more. -> did not work

And figured for sure atleast they can be reset through the robot interpreter. -> did not work

The program below does not reset the $CYCFLAG, and yes I tested that it is not only the user interface that is slow. It really does not get reset or cleared.

KSS is 8.7.3 and this is tested on officelite running on a hyper-v machine.

Any ideas? Have I misunderstood this completely? or can anyone else reproduce this?

The code:

Code

DEF ErrorTest2 ( )
DECL INT i1

FOR i1=1 TO 10
   $CYCFLAG[2] = $OUT[2]
   MsgNotify("$CYCFLAG[2] should have been set")
   WAIT SEC 2
   $CYCFLAG[2] = FALSE
   MsgNotify("$CYCFLAG[2] should have been reset")
   WAIT SEC 2
ENDFOR

END

Display More

** update: they do eventually get reset but it may take minutes?!?

**panic mode** · May 27th 2022

the whole idea behind cyclical flags is that you assign expression to it - once.... after that just evaluate it (read it) and stop updating it. you are doing the opposite... you are constantly writing new expression to cyclical flag and interfering with its existing value.

consider this robot program (not submit). note that inside loop we are not doing anything with the flag. keep moving $OV_PRO slider and look at the flag value. cyclical means that flag value is constantly (cyclically) updated while program is doing something else.

Code

DEF TEST()

; turn flag on if OV_PRO is 50% or higher
$CYCFLAG[1]=$OV_PRO>=50

LOOP
   WAIT SEC 1 ; simulate something else being done
ENDLOOP

END

**panic mode** · May 27th 2022

Submit itself is a cyclical task that gets processed continuously.

not sure why would one need cyclical flag there...

Hes · May 27th 2022

I think you are getting the wrong idea.

The submit is beside the point. I can assign a $CYCFLAG to whatever in a robot program *.src just fine and it will be assigned almost instantly. I can also change the assignment to something else and the assignment will update just fine. But I cannot set it to FALSE (stop evaluating). Or atleast the assignment will keep on hanging there for a couple of minutes before it actually gets reset.

What I wanted to do in submit was set the given $CYCFLAG=FALSE under a specific set of circumstances.

But when I couldn´t get that working I tested it further I do not seem to be able to even set a cycflag to false in a robotprogram.

The code provided is dumbed down and does not serve any real world purpose anymore but illustrates my issue.

Even if I do this I cannot get it reset within a decent time:

Code

DEF ErrorTest2 ( )

$CYCFLAG[2] = $OUT[2] ;<-This will be set instantly
MsgNotify("$CYCFLAG[2] should have been assigned to $OUT[2]")
WAIT SEC 2
$CYCFLAG[2] = $OUT[3] ;<-This will be set instantly
MsgNotify("$CYCFLAG[2] should have been assigned to $OUT[3]")
WAIT SEC 2
$CYCFLAG[2] = FALSE ;<-This assignment will linger for minutes before being set..
MsgNotify("$CYCFLAG[2] should have been reset")
WAIT SEC 2

END

Display More

**panic mode** · May 27th 2022

pretty sure that i am not missing much if anything. after all everything works as expected for me.

Hes · May 27th 2022

You are correct. I tested the same as you and it seems like my interpretation of the description from the manual is not correct.

I will rephrase my question: Is there any way to deactivate a $CYCFLAG or change its assignment from a submit?

**panic mode** · May 27th 2022

manual looks pretty clear on things for me. Cyclical evaluation occurs only in Robot program - as intended. in other interpreters it acts like a normal flag. Submit interpreters are not high priority tasks, they are not synchronous to robot program. why are you trying to do things backwards? use things as they are intended to. and cyclical flags are meant to be used in robot program - not submit. you can assign expression to it ... and forget about it. when program is deselected you can reset the flag in submit if that is what you need.

note that in this example submit is not used - program is run in robot interpreter.

also outputs are replaced with flags so they can be set while robot program is running.

cyclical flag is assigned expression at the begin of program only and the value is still changing according to expression - until cyclical flag is turned off (IF statement).

pasted-from-clipboard.mp4

Hes · May 28th 2022

I think this issue is resolved and settled. Things did not work as I expected but with this knowledge I can maneuver around it. Kudos for the effort!

Hes · May 28th 2022

For who might be interested.

What I wanted to achieve was a generic error handler. That would be as flexible as possible to use.

I wanted to be able to catch e.g. variables out of range at specific checkpoints, inputs during motion, etc.

After the above discussion I´ve concluded that it is not an optimal solution.

The code below "works" but still leaves alot of gaps. e.g. there is to my knowledge no way of deactivating the cyclic monitoring for error triggering ~~if the program was deselecte~~d or lines skipped...

Code is in no way optimal and it is possible and even likely to end up at stalemates. And it will never be an interrupt no matter how much lipstick you put on it. Even as this was meant for errors that do not require optimal response time. As an example it was meant for errorhandling after robot drops a label and it does not really matter how quickly it stops. It was not meant for searching for labels from a stack that will make a hard stop in a few mm´s

My initial thoughts were that using $PROG_INFO[1] with interrupts would not be useful as the program pointer would have escaped into the ISR and would provide no information of any use. I do not know this with certainty. Intention was to indicate where the pointer was when the error was triggered and not trap the user in a ISR with no knowledge or background how they ended up there. That is the reason I went with this approach. I also liked the idea of using ROB_STOP() to actually prohibit motion and jogging until the error was cleared. Which to my knowledge is only usable in a submit.

At this point I do not see an easy way to make a flexible interrupt that would always be declared and regardless of which program was started (Interrupt declared and set to on from submit?). And a way to trigger said interrupt with either signals, ins, outs, flags, vars, etc.

I will mark this thread as resolved but leave it here for whoever it may benefit.

This sub does the errortrapping and handling:

Code

DEF ErrorTrap ( )

DECL INT i1
DECL BOOL b1, b2
DECL STATE_T Stat
DECL MODUS_T Mode
DECL INT ErrorMem


;INIT
Mode = #SYNC
ErrorMem = 0
ErrorSource[] = " "
ErrorLine = 0

LOOP
   IF ErrorHandlerDisable == FALSE THEN 
      IF $PRO_STATE1 <> #P_FREE THEN
         FOR i1=1 TO 20
            IF Error[i1].Active == TRUE THEN 
               ErrorTrig = TRUE
               ErrorMem = i1
               ErrorSource[] = $PROG_INFO[1].PRO_IP_NAME[]
               ErrorLine = $PROG_INFO[1].PRO_IP_SNR
               IF Error[i1].Recoverable == FALSE THEN ;If not recoverable set bool to abort
                  ErrorAbort = TRUE
                  ;b1 = ROB_STOP(#RAMP_DOWN) ;Stop and block robot interpreter, ROB_STOP here to prevent jogging only non recoverable errors
               ENDIF
               ;b1 = ROB_STOP(#RAMP_DOWN) ;Stop and block robot interpreter, ROB_STOP here to prevent jogging on all errors
               EXIT ;Exit loop after first error msg is found
            ELSE
               ErrorMem = 0
            ENDIF
         ENDFOR      
         
         IF NOT ErrorCycTriggered THEN ;Prioritize Errors from $CYCFLAG by overwriting  
            IF $CYCFLAG[ErrorCycFlag] == TRUE THEN
               ErrorCycTriggered = TRUE
               ErrorTrig = TRUE
               ErrorMem = ErrorCycBind
               ErrorSource[] = $PROG_INFO[1].PRO_IP_NAME[]
               ErrorLine = $PROG_INFO[1].PRO_IP_SNR
               IF Error[ErrorCycBind].Recoverable == FALSE THEN ;If not recoverable set bool to abort
                  ErrorAbort = TRUE
                  ;b1 = ROB_STOP(#RAMP_DOWN) ;Stop and block robot interpreter ,ROB_STOP here to prevent jogging only non recoverable errors
               ENDIF
               ;b1 = ROB_STOP(#RAMP_DOWN) ;Stop and block robot interpreter, ROB_STOP here to prevent jogging on all errors
            ENDIF
         ENDIF
               
         IF ErrorAbort AND ErrorTrig AND (ErrorMem <> 0) THEN
            b1 = ROB_STOP(#RAMP_DOWN)
         ENDIF
      ENDIF

      ;If Error has been triggered and program is running, stop it
      ;and generate error message
      IF (ErrorTrig==TRUE) AND ($PRO_STATE1 <> #P_FREE) THEN
         CWRITE ($CMD, Stat, Mode, "STOP 1") ;Stop robot interpreter
         WAIT FOR $PRO_STATE1 <> #P_ACTIVE
         ;MsgNotifyTextPar("Source: %2  Line: %1", "ErrorHandler", ErrorLine, ErrorSource[], , Error[ErrorMem].No)
         MsgQuit("Source:%2  Line:%1","ErrorHandler", ErrorLine, ErrorSource[], Error[ErrorMem].No)
         MsgQuit(Error[ErrorMem].Msg[],"ErrorHandler")
      ENDIF
      
      ;If Error has been triggered and Abort is necessary
      IF (ErrorTrig==TRUE) AND (ErrorAbort==TRUE) AND ($PRO_STATE1 <> #P_FREE) THEN
         MsgQuit("Error is not recoverable, program will be deselected.","ErrorHandler")
         CWRITE ($CMD, Stat, Mode, "CANCEL 1") ;Cancel robot interpreter
         WAIT FOR $PRO_STATE1 == #P_FREE
      ENDIF
      
      ;If Error has been triggered and Abort is NOT necessary
      IF (ErrorTrig==TRUE) AND (ErrorAbort==FALSE) AND ($PRO_STATE1 <> #P_FREE) THEN
         MsgQuit("Error is recoverable, ackn to continue","ErrorHandler")
      ENDIF
   
      ;Reset
      IF ErrorTrig == TRUE THEN
         IF ErrorMem <> 0 THEN
            Error[ErrorMem].Active = FALSE ;Reset active errors
            Error[ErrorMem].Tracking = Error[ErrorMem].Tracking + 1
         ENDIF
         ErrorAbort = FALSE ;Reset abort bool
         ErrorTrig = FALSE ;Reset trig
         ;$CYCFLAG[ErrorCycFlag] = FALSE ;Reset cycflag for error monitoring <- Does not work
         ;ErrorReset() ;<- Set $CYCFLAG[ErrorCycFlag]=FALSE in a *.src, does not work
         ;$CYCFLAG[ErrorCycFlag] = $IN[1026] ;<- DOES NOT WORK IN SUBMIT
         ;WAIT FOR $CYCFLAG[ErrorCycFlag] == FALSE
         b2 = STRCLEAR(ErrorSource[])
         ErrorLine = 0
         ROB_STOP_RELEASE()        
      ENDIF
         
      IF ErrorForceRelease THEN
         ROB_STOP_RELEASE()
      ENDIF
   ENDIF      
ENDLOOP

END

Display More

This would be declared in config.dat:

Code

;ErrorTrap
DECL BOOL ErrorTrig=FALSE ;Used for triggering Error handler interrupt
DECL CHAR ErrorSource[24]
ErrorSource[]=" "
DECL INT ErrorLine=0
DECL BOOL ErrorAbort=FALSE
DECL BOOL ErrorHandlerDisable=FALSE ;Disable Errorhandling
DECL INT ErrorCycFlag=1 ;No for binding of errorhandler cyclicflag
DECL INT ErrorCycBind=4 ;Currently bound error number to cyclic flag
DECL BOOL ErrorCycTriggered=TRUE
DECL BOOL ErrorForceRelease=FALSE

;Defined errors
STRUC ErrorType BOOL Active,INT No,CHAR Msg[80],BOOL Recoverable,INT Tracking
DECL ErrorType Error[20]
Error[1]={Active FALSE,No 1,Msg[] "Variable value is not ok",Recoverable FALSE,Tracking 4}
Error[2]={Active FALSE,No 2,Msg[] "Variable is out of range",Recoverable TRUE,Tracking 10}
Error[3]={Active FALSE,No 3,Msg[] " ",Recoverable FALSE,Tracking 0}
Error[4]={Active FALSE,No 4,Msg[] "Cyclic monitored error triggered",Recoverable TRUE,Tracking 28}
Error[5]={Active FALSE,No 5,Msg[] " ",Recoverable FALSE,Tracking 0}
Error[6]={Active FALSE,No 6,Msg[] " ",Recoverable FALSE,Tracking 0}
Error[7]={Active FALSE,No 7,Msg[] " ",Recoverable FALSE,Tracking 0}
Error[8]={Active FALSE,No 8,Msg[] " ",Recoverable FALSE,Tracking 0}
Error[9]={Active FALSE,No 9,Msg[] " ",Recoverable FALSE,Tracking 0}
Error[10]={Active FALSE,No 10,Msg[] " ",Recoverable FALSE,Tracking 0}
Error[11]={Active FALSE,No 11,Msg[] " ",Recoverable FALSE,Tracking 0}
Error[12]={Active FALSE,No 12,Msg[] " ",Recoverable FALSE,Tracking 0}
Error[13]={Active FALSE,No 13,Msg[] " ",Recoverable FALSE,Tracking 0}
Error[14]={Active FALSE,No 14,Msg[] " ",Recoverable FALSE,Tracking 0}
Error[15]={Active FALSE,No 15,Msg[] " ",Recoverable FALSE,Tracking 0}
Error[16]={Active FALSE,No 16,Msg[] " ",Recoverable FALSE,Tracking 0}
Error[17]={Active FALSE,No 17,Msg[] " ",Recoverable FALSE,Tracking 0}
Error[18]={Active FALSE,No 18,Msg[] " ",Recoverable FALSE,Tracking 0}
Error[19]={Active FALSE,No 19,Msg[] " ",Recoverable FALSE,Tracking 0}
Error[20]={Active FALSE,No 20,Msg[] " ",Recoverable FALSE,Tracking 0}

Display More

And this is an example to test with:

Code

DEF Errortest1 ( )

DECL INT i1
DECL INT Var1, Var2
DECL AXIS P1, P2, P3

IF $MOVE_BCO THEN
;FOLD INI;%{PE}
  ;FOLD BASISTECH INI
    GLOBAL INTERRUPT DECL 3 WHEN $STOPMESS==TRUE DO IR_STOPM ( )
    INTERRUPT ON 3 
    BAS (#INITMOV,0 )
  ;ENDFOLD (BASISTECH INI)
  ;FOLD USER INI
    ;Make your modifications here
  ;ENDFOLD (USER INI)
;ENDFOLD (INI)
ENDIF

Var1 = 11
Var2 = 9
P1 = {A1 0,A2 -90, A3 90, A4 0, A5 0, A6 0}
P2 = {A1 50,A2 -90, A3 80, A4 -30, A5 20, A6 100}
P3 = {A1 100,A2 -90, A3 90, A4 30, A5 30, A6 240}

SPTP P1
WAIT FOR TRUE
;Catch a recoverable error that may occur with a specific check.
IF Var1 > 10 THEN
   Error[2].Active = TRUE ;<- Recoverable error
ENDIF

SPTP P3

ErrorCycBind = 4 ;Bind cyclic error handling to an error number
ErrorCycTriggered = FALSE ;Set oneshot bool to FALSE to allow errorhandler to process the error to be mointored
TRIGGER WHEN DISTANCE=0 DELAY=0 DO $CYCFLAG[ErrorCycFlag] = $FLAG[1] ;Assign cycflag to whatever is to be monitored
SPTP P1 ;Error can be triggered from start of this motion..
SPTP P2 
SPTP P3 ;..to the end of this motion
TRIGGER WHEN DISTANCE = 0 DELAY=0 DO $CYCFLAG[ErrorCycFlag] = FALSE ;Deactivate cyclicflag and hence monitoring 

SPTP P1 ;This one will be unaffected

WAIT FOR TRUE
;Catch a non-recoverable error that may occur with a specific check.
IF Var2 < 10 THEN
   Error[1].Active = TRUE ;<- Non recoverable error
ENDIF

END

Display More

$CYCFLAG mysterious behaviour

Advertising from our partners

How to see your Job Posting (search or recruit) here in Robot-Forum.com

Robotics Technician - Detroit/Ann Arbor area - Radwell International

Share

Similar Threads

KRC1 no connection to kernel system

Tags

Users Viewing This Thread