What is the correct way to get coordinates from external device ?

Zadok the priest · Apr 21st 2022

Hi everyone,

I am new on the KUKA.

KUKA side:

- KSS 8.3.42

- KR300 R2500

- Profinet&Profisafe 3.2.4 - package

PLC side:

- S7 1511 TF

- TiaPortal v15

Note : I have no safety interface board. I am using Profisafe communication for safety.

Now, I guess i am in trouble with that content. I have profinet communication. And my work is sorting project. The coordinates of the objects I will sort will be sent to me from outside. And the coordinates of all these pieces are sent to me at once. Maybe 10 pieces, maybe 20 pieces. My questions are:

1- Is it possible to import .dat and .src files from external device directly to the robot while the robot is running in automatic mode?

2- When i researching in this perfect forum, i saw that CWRITE/CREAD functionalities. When i examined that documents, i have to do CREAD function for reading file where is in the UserFiles folder. Is it possible to read over Profinet connection ? And also, Can external device create files to this folder?

3- And in the other hand, when the robot in auto mode, can external device create a new .dat files in R1/Program folder ? And Can this file be updated ? Or is there any other way ?

If all these questions get negative answers, Please can you suggest the most logical and applicable solution to solve this problem?

Thanks in advance sir!..

hermann · Apr 21st 2022

1. Yes, but you need an option 'directory loader' (Iirc), but have no idea how you want to write those files with your Siemens plc.

2. Cread can't read from profinet. But an external device can create files that can be read with cread/cwrite. Create a standard windows share, then you can write files during auto mode. But you have to be shure robot and external device don't access the file at the same time.

3. Same as in 1 and 2. You need the option, and you can update files over a windows share.

I would prefer 2.

For the option (directory loader) you need to spend extra money and it is a bit fiddly to configure and to use.

Zadok the priest · Apr 21st 2022

Thank you for your quick answer hermann.

Quote from hermann

1. Yes, but you need an option 'directory loader' (Iirc), but have no idea how you want to write those files with your Siemens plc.

1- Actually, my external device is not siemens plc. I use windows-based pc. So, using the 'Directory loader' package, I can update the .src and .dat files that I call within the code, even though the robot program is not stopped and robot automatic (only AUT mode) running?

2- Okay, i will update files over a windows share. [C:/KRC/ROBOTER/UserFiles/] Is this the path where I need to create the file? Can I use another path?

3- Also, I read CWRITE/CREAD doc. However, i couldn't understand brightly.

My coordinates points are : x,y,z,a,b,c

Mytest.txt:

154.6, 177.4, 196.8, 57.4, 87.6, 71.3

1444.6, 557.3, 196.8, 57.4, 88.0, 66.8

1665.4, 544.7, 196.8, 77.5, 74.3, 65.1

For example mytest.txt file has a 3 line info about coordinates. I want to read these points and then seperate them. Could you give me example about that ? I want to read from "[C:/KRC/ROBOTER/UserFiles/Mytest.txt]"

Thank you in advance...

**panic mode** · Apr 21st 2022

1 - you may want to check the manual for directory loader. it i recall there are some limitations.

2 - that is possible (check mounting of volume). not really worth the effort if you ask me.

3 - several examples (including ones from me) are already shared. basically open file, read from file, close the file. you can try to parse the values immediately in CWRITE or separately using SREAD. both are very similar but SREAD is a bit more flexible and forgiving.

Code

 DEF read_txt()
DECL state_t s
DECL modus_t m
DECL int h,read,n
DECL char Buff[256]

; initialize buffer, it cannot be empty
for n=1 to 256
  Buff[n]=32 ; 0x20 is a space character
endfor

h=0      ; pick file handle 
read=0   ; initialize number of characters read from file  



;-------> step 1 - open file <------------
; note: file is stored in C:\KRC\ROBOTER\USERFILE
cwrite($FCT_CALL,S,M,"krl_fopen","PosArray.txt","r",h)
wait for s.ret1==#data_ok ; confirm action 




;-------> step 2 - read from file <-------
repeat
  cwrite($FCT_CALL,s,m,"krl_fgets",h,Buff[],87,Read,";")
  wait for (s.ret1==#data_ok) or (s.msg_no== -4) ; confirm action or end of file
    
  if (s.ret1==#data_ok) and (StrLen(Buff[])>0) then
    MsgNotify(Buff[],,,,read) ; display what was read and number of chars
  endif

  if s.msg_no== -4 then
    msgnotify("end of file") ; it is end of file...
  endif

until s.msg_no == -4



;-------> step 3 - close file  <----------
; do NOT forget to close file (or else...)
cwrite($FCT_CALL,S,M,"krl_fclose",h)
wait for s.ret1==#data_ok

END

Display More

el_dk · Apr 21st 2022

Is there a reason why you would not just send over the coordinates as data using PROFINET communication?

Declare 6 x 10 REAL variables, and a few BOOL signals as flags, to check if values have updated.

Robot check flags cyclically, to see if variables has been updated, if so, use REAL values to create a E6POS, and start motion.

Forgive me if I am missing the point of your question, but I am genuinly curious, what advantages does transfer by text-files have, when PROFINET communication is available.

**panic mode** · Apr 21st 2022

out of curiosity, why do you think that PROFINET communication is available? the robot and PLC support ProfiNet but he already stated the data is actually arriving from PC.

There are software stacks for Profinet and some are free but this is not quite as simple as writing text file. Just a guess...

Zadok the priest · Apr 22nd 2022

Quote from panic mode

1 - you may want to check the manual for directory loader. it i recall there are some limitations.

2 - that is possible (check mounting of volume). not really worth the effort if you ask me.

3 - several examples (including ones from me) are already shared. basically open file, read from file, close the file. you can try to parse the values immediately in CWRITE or separately using SREAD. both are very similar but SREAD is a bit more flexible and forgiving.

Code

 DEF read_txt()
DECL state_t s
DECL modus_t m
DECL int h,read,n
DECL char Buff[256]

; initialize buffer, it cannot be empty
for n=1 to 256
  Buff[n]=32 ; 0x20 is a space character
endfor

h=0      ; pick file handle 
read=0   ; initialize number of characters read from file  



;-------> step 1 - open file <------------
; note: file is stored in C:\KRC\ROBOTER\USERFILE
cwrite($FCT_CALL,S,M,"krl_fopen","PosArray.txt","r",h)
wait for s.ret1==#data_ok ; confirm action 




;-------> step 2 - read from file <-------
repeat
  cwrite($FCT_CALL,s,m,"krl_fgets",h,Buff[],87,Read,";")
  wait for (s.ret1==#data_ok) or (s.msg_no== -4) ; confirm action or end of file
    
  if (s.ret1==#data_ok) and (StrLen(Buff[])>0) then
    MsgNotify(Buff[],,,,read) ; display what was read and number of chars
  endif

  if s.msg_no== -4 then
    msgnotify("end of file") ; it is end of file...
  endif

until s.msg_no == -4



;-------> step 3 - close file  <----------
; do NOT forget to close file (or else...)
cwrite($FCT_CALL,S,M,"krl_fclose",h)
wait for s.ret1==#data_ok

END

Display More

Thank you for your great example, panic mode. I used that piece of code and it is working. However, I want to assign that read values to variables. I added a few line to your example code.

Code

DEF read_test()
DECL state_t s
DECL modus_t m
DECL int h,read,n, split,o
DECL char f1[100], f2[100], f3[100]

; %f  (for REAL type)
; %s  (for char type)

f1[]="%f %f %f %f %f %f "
f2[]="%f %f %f %f %f %f "
f3[]="%f %f %f %f %f %f "

for n=1 to 256
  Buff[n]=32 
endfor

h=0      
read=0   

;-------> step 1 - open file <------------
; note: file is stored in C:\KRC\ROBOTER\USERFILE
cwrite($FCT_CALL,S,M,"krl_fopen","coordata.txt","r",h)
wait for s.ret1==#data_ok 




;-------> step 2 - read from file <-------
n=1 

repeat

  
  cwrite($FCT_CALL,s,m,"krl_fgets",h,Buff[],100,Read)

  wait for (s.ret1==#data_ok) or (s.msg_no== -4)
  if s.ret1==#data_ok then

changeseperator(Buff[])
    o=0 
   MsgNotify(Buff[],,,,read)     

  SWITCH n
    CASE 1
    sread(Buff[],s,o,f1[],v1,v2,v3,v4,v5,v6)
    CASE 2
    sread(Buff[],s,o,f2[],v7,v8,v9,v10,v11,v12)
    CASE 3
    sread(Buff[],s,o,f3[],v13,v14,v15,v16,v17,v18)
    DEFAULT 
     HALT
  ENDSWITCH 

    n=n+1   

  endif 

until s.msg_no == -4


;-------> step 3 - close file  <----------
cwrite($FCT_CALL,S,M,"krl_fclose",h)
wait for s.ret1==#data_ok

END
DEF changeseperator(fiBuff[]:OUT)

DECL Char fiBuff[]
DECL INT cloop

  for cloop=1 TO StrLen(fiBuff[])
    if fiBuff[cloop]=="," then 
      fiBuff[cloop]=" "
    endif
  endfor


END

Display More

The number of coordinates that will come to me from outside will be able to change. In other words, 4 coordinate lines can come, 15 coordinate lines can also come.

If you noticed this code that I added, it is possible to process 3 lines of coordinate information. I want to make this code dynamic. In other words, it needs to create as many variables as the number of coordinate lines that will come from the outside and write the value into it.

When I send 2 coordinate lines instead of 3 in the .txt file that the current code is reading, my code stuck line 37 -wait for condition. Since there are already two lines of coordinate information and the reading is over, it shouldn't be stuck there, right?. How can I prevent this? We can accept the maximum coordinate line that will come to me from the outside as 100. Is there any chance you can help me with this problem I described?

Thank you in advance.

Zadok the priest · Apr 22nd 2022

Quote from el_dk

Is there a reason why you would not just send over the coordinates as data using PROFINET communication?

Declare 6 x 10 REAL variables, and a few BOOL signals as flags, to check if values have updated.

Robot check flags cyclically, to see if variables has been updated, if so, use REAL values to create a E6POS, and start motion.

Forgive me if I am missing the point of your question, but I am genuinly curious, what advantages does transfer by text-files have, when PROFINET communication is available.

Display More

Yes, that is an option of course. However, like said panic mode, this option will be too much of a burden for me in terms of software, algorithm and controlling many things. Thank you so much for suggestion.

**panic mode** · Apr 22nd 2022

you mean something like this?

**SkyeFire** · Apr 22nd 2022

It's been a while, but I had a program where I loaded massive amounts of XYZABC data from a text file whose line count was unknown. FEOF is the function that's supposed to detect the end of the file, but I found it unreliable at the time. However, also checking for an error on FGETS worked for me.

Code

    REPEAT
      WAIT FOR STRCLEAR (_chBuffer[])
      _chBuffer[1] = "x"
      WAIT FOR STRCLEAR (chBuffer[])
      CWRITE ($FCT_CALL, _FgetsState, _Mode, "krl_fgets", _nFileHandle, _chBuffer[], _nFGetsLength, _nCharsRead)
      CWRITE ($FCT_CALL, _EOFState, _Mode, "krl_feof", _nFileHandle, _bEOF)
      IF NOT _bEOF THEN
        Increment (_nFileLineCount)
        SWITCH _FgetsState.RET1
        CASE #CMD_ABORT
          _nOffset = 0
          WAIT FOR STRCLEAR (_chBuffer[])
          SWRITE (_chBuffer[], _State, _nOffset, "FGETS ERROR %d at file line %d", _FgetsState.MSG_NO, _nFileLineCount)
          UserDialog (_chBuffer[], "LoadResidualFeedback",,,UserButtonOK[], _nDialogAnswer)
          bAbortAll = TRUE
          _bLoadError = TRUE
        CASE #DATA_OK
          chBuffer[]  = _chBuffer[]
          ;MsgNotify (_chBuffer[])
          nCharsRead = _nCharsRead
          ; Parse Robot/Tool/Base data
          _nOffset = 0
          ON_ERROR_PROCEED
          SREAD (chBuffer[], _SreadState, _nOffset, "%4d,%4d,%4d,%4d", _nFileRobotNumber, _nToolsBinary, _nToolDuringMeasIdx, _nBaseDuringMeasIdx)
          _bLoadError = ($ERR.NUMBER <> 0)
          ; Parse RefPos/Correction data
          Increment (_nOffset)
          ON_ERROR_PROCEED
          SREAD (chBuffer[], _SReadState, _nOffset, "%8f,%8f,%8f,%8f,%8f,%8f,%8f,%8f,%8f", _fRFReference.X,_fRFReference.Y,_fRFReference.Z,_fRFReference.A,_fRFReference.B,_fRFReference.C,_fRFCorrection.X,_fRFCorrection.Y,_fRFCorrection.Z)
          _bLoadError = (_bLoadError OR ($ERR.NUMBER <> 0))
          IF _bLoadError THEN
            _nOffset = 0
            WAIT FOR STRCLEAR (_chBuffer[])
            Increment (_nArrayIndex)
            SWRITE (_chBuffer[], _State, _nOffset, "Error in SREAD at file line %d", _nFileLineCount)
            UserDialog (_chBuffer[], "LoadResidualFeedback",,,UserButtonOK[], _nDialogAnswer)
            _bLoadError = TRUE
            bAbortAll = TRUE
          ELSE
            IF (_nFileRobotNumber == _nRobotnumber) THEN
              Increment (_nArrayIndex)
              IF (_nArrayIndex <= nRFArraySize) THEN
                RFArray[_nArrayIndex].ToolsBinary           = _nToolsBinary
                RFArray[_nArrayIndex].ToolDuringMeasurement = _nToolDuringMeasIdx
                RFArray[_nArrayIndex].BaseDuringMeasurement = _nBaseDuringMeasIdx
                RFArray[_nArrayIndex].ReferencePosition     = _fRFReference
                RFArray[_nArrayIndex].Correction            = _fRFCorrection
              ELSE
                UserDialog ("More lines in master file than available in RFArray", "LoadResidualFeedback",,,UserButtonOK[], _nDialogAnswer)
                bAbortAll = TRUE
                _bLoadError = TRUE
              ENDIF
            ENDIF
          ENDIF
        DEFAULT
          UserDialog("Unknown FGETS error", "LoadResidualFeedback",,, UserButtonOK[], _nDialogAnswer)
          bAbortAll = TRUE
        ENDSWITCH
      ELSE
        MsgNotify("End of File reached.  Found %1 Entries", "LoadResidualFeedback", _nArrayIndex)
        bRFFileLoaded = TRUE    
      ENDIF
    UNTIL (_bEOF or _bLoadError)

Display More

CWRITE KRL_FGETS was used to get one line from the text file, then SREAD was used to parse the line into individual variables. I had to use two SREADs because a single SREAD command is limited to parsing 10 variables, and my data file was 13 columns of CSV data. The data file was generally about 5000-6000 lines.

Code

0001,0011,0001,0001,-0444.72,+0164.12,+0515.28,+0115.25,+0045.24,-0131.36,+01.6864,-01.7515,+00.4082
0001,0011,0001,0001,-0444.73,+0191.04,+0472.20,+0115.25,+0045.24,-0131.36,+01.6575,-01.7148,+00.3547
0001,0011,0001,0001,-0444.73,+0217.96,+0429.12,+0115.25,+0045.24,-0131.36,+01.6442,-01.7317,+00.1482
0001,0011,0001,0001,-0444.73,+0244.88,+0386.03,+0115.25,+0045.24,-0131.36,+01.5727,-01.7569,+00.1678
0001,0011,0001,0001,-0444.73,+0271.80,+0342.95,+0115.25,+0045.24,-0131.36,+01.5679,-01.7372,+00.1564
0001,0011,0001,0001,-0444.74,+0298.72,+0299.87,+0115.25,+0045.24,-0131.36,+01.5799,-01.7068,+00.0550
0001,0011,0001,0001,-0422.42,+0167.27,+0487.29,+0115.25,+0045.24,-0131.36,+01.6379,-01.6690,+00.4336
0001,0011,0001,0001,-0422.43,+0194.19,+0444.21,+0115.25,+0045.24,-0131.36,+01.6643,-01.7548,+00.3164
0001,0011,0001,0001,-0422.43,+0221.11,+0401.13,+0115.25,+0045.24,-0131.36,+01.5892,-01.7421,+00.2668
0001,0011,0001,0001,-0422.43,+0248.03,+0358.05,+0115.25,+0045.24,-0131.36,+01.5663,-01.7253,+00.1189
0001,0011,0001,0001,-0422.43,+0274.95,+0314.97,+0115.25,+0045.24,-0131.36,+01.5673,-01.6983,+00.0095
0001,0011,0001,0001,-0422.44,+0301.87,+0271.89,+0115.25,+0045.24,-0131.36,+01.5501,-01.7293,-00.0848
0001,0011,0001,0001,-0377.82,+0133.19,+0495.95,+0115.25,+0045.24,-0131.36,+01.5943,-01.6577,+00.5030
0001,0011,0001,0001,-0377.82,+0160.11,+0452.87,+0115.25,+0045.24,-0131.36,+01.5977,-01.6325,+00.2371
0001,0011,0001,0001,-0377.82,+0187.03,+0409.79,+0115.25,+0045.24,-0131.36,+01.6353,-01.7286,+00.2095
0001,0011,0001,0001,-0377.83,+0227.41,+0345.17,+0115.25,+0045.24,-0131.36,+01.5604,-01.7185,+00.1607
0001,0011,0001,0001,-0377.83,+0254.34,+0302.08,+0115.25,+0045.24,-0131.36,+01.4902,-01.6073,-00.0393
0001,0011,0001,0001,-0377.83,+0281.26,+0259.00,+0115.25,+0045.24,-0131.36,+01.5197,-01.6741,-00.1791
0001,0011,0001,0001,-0400.13,+0224.26,+0373.15,+0115.25,+0045.24,-0131.36,+01.5819,-01.7203,+00.2662
0001,0011,0001,0001,-0400.13,+0251.18,+0330.07,+0115.25,+0045.24,-0131.36,+01.5584,-01.7689,+00.0140
0001,0011,0001,0001,-0400.13,+0278.10,+0286.99,+0115.25,+0045.24,-0131.36,+01.5048,-01.6618,+00.0237
0001,0011,0001,0001,-0400.14,+0305.02,+0243.91,+0115.25,+0045.24,-0131.36,+01.5501,-01.6724,-00.0962
0001,0011,0001,0001,-0445.10,+0348.32,+0197.38,+0124.85,+0058.29,-0119.23,+01.8936,-01.6545,+00.1533
0001,0011,0001,0001,-0445.10,+0363.17,+0148.80,+0124.85,+0058.29,-0119.23,+01.9087,-01.6762,-00.0055
0001,0011,0001,0001,-0445.11,+0378.02,+0100.22,+0124.85,+0058.29,-0119.23,+01.8774,-01.7123,-00.1541
0001,0011,0001,0001,-0445.11,+0392.88,+0051.64,+0124.85,+0058.29,-0119.23,+01.8858,-01.7314,-00.3341
0001,0011,0001,0001,-0445.11,+0407.73,+0003.06,+0124.85,+0058.29,-0119.23,+01.8939,-01.6861,-00.3640
0001,0011,0001,0001,-0445.11,+0422.58,-0045.51,+0124.85,+0058.29,-0119.23,+01.9330,-01.7526,-00.5015
0001,0011,0001,0001,-0422.80,+0344.12,+0169.54,+0124.85,+0058.29,-0119.23,+01.8797,-01.7132,+00.1655

Display More

Zadok the priest · Apr 26th 2022

Hello again,

Sorry for the late response. Today I was able to find time to try to these codes. And thank you so much panic mode and SkyeFire. Both of them working..!

What is the correct way to get coordinates from external device ?

Advertising from our partners

How to see your Job Posting (search or recruit) here in Robot-Forum.com

Robotics Technician - Detroit/Ann Arbor area - Radwell International

Share