KAREL to Write Robot I/O Comment

I'm by no means a Karel Expert, but I've dabbled.

Yes you are on the right path.

SET_PORT_CMT can be used to set I/O comments

You may also want to look at SET_REG_CMT, SET_PREG_CMT, SET_SREG_CMT for registers, Position Registers, and String Registers.

Reading Arguments can be accomplished with GET_TPE_PRM.

Honestly, It probably sounds like more than it really is. Curiosity got to me, so I tried it myself, and it wasn't that much code.

If you're interested, below is how I accomplished it.

I'm sure there is probably more error checking that can be done with the STATUS variables, but I don't know much about them, I got them out of another source code I had a copy of.

I followed the AR[] structure from your original post; AR[1] = IO_type, AR[2] = IO_Num, AR[3] = IO_cmt.

The IO_type variable gets passed as an integer who's value comes from KLIOTYPS.KL (See the list below) and then I have a SELECT CASE setup for the Registers; pass a 1000, 1001, or 1002 for Num-Reg, Pos-Reg, or String-Reg respectively.

(Setting this program up in ARGDISPEG01.DT would also be a good idea)

io_din = 1 -- Digital input

io_dout = 2 -- Digital output
io_anin = 3 -- Analog input
io_anout = 4 -- Analog output

io_rdi = 8 -- Robot digital input
io_rdo = 9 -- Robot digital output

io_gpin = 18 -- Grouped inputs
io_gpout = 19 -- Grouped outputs

io_flag = 35 -- Flag (F[ ])
io_marker = 36 -- Marker (M[ ])

PROGRAM ARG_CMTS
%NOPAUSE = TPENABLE
%COMMENT = 'ROBOT COMMENTS'
%ENVIRONMENT REGOPE
%ENVIRONMENT IOSETUP
%ENVIRONMENT STRNG
%INCLUDE kliotyps

VAR
    int_value, STATUS, IO_Num, IO_type   :INTEGER
    real_value  :REAL
    IO_cmt, str_value  : STRING[32]
    
    
BEGIN
    GET_TPE_PRM(1, 1, IO_type, real_value, str_value, STATUS)
    GET_TPE_PRM(2, 1, IO_Num, real_value, str_value, STATUS)
    GET_TPE_PRM(3, 3, int_value, real_value, IO_cmt, STATUS)
    
    IF IO_type >= 1000 THEN
        SELECT IO_type OF
        CASE(1000):
           SET_REG_CMT (IO_Num, IO_cmt, STATUS)
       CASE(1001):
           SET_PREG_CMT (IO_Num, IO_cmt, STATUS)
       CASE(1002):
           SET_SREG_CMT (IO_Num, IO_cmt, STATUS)
        ENDSELECT
    ELSE
        SET_PORT_CMT(IO_type, IO_Num, io_cmt, STATUS)
    ENDIF

 END ARG_CMTS

Quote from iProg83

I was reading in my manual yesterday about KLIOTYPS.KL. I was unable to find any of this when I searched in my manual. I was really hoping there was more about it in the appendix.

I found the KLIOTYPS list on this thread KLIOTYPS.KL

Glad I could help.