Servo tracking error axis L and B

    The robot is losing track of where it’s at in a pile of slip sheets. It will pick one up, it’s then supposed to record where it picked that one up, store the location , then return to that location for the next slip sheet minus a small offset. What’s happening is the robot is slamming into the pile and this error populates. I’ve looked at the variables it’s supposed to record the last position in, and it never changes. Should the position variable be different on the next pickup ?

    Quote from cat91345

    What’s happening is the robot is slamming into the pile and this error populates. ?

    So why you in the first post you ask the reason of you errors: you get a servo track if you slam the robot :hmmm: .

    How do you calculate your offset, how do you pass your shift to the variable?

    if you can post your code maybe someone could have a look?

    There are tons of program solution to your problem but I don't know the one your're trying.

    Here is the job we are having problems with. As i said, it's losing track of where it's at in a pile of slip sheets and tries to get to the bottom. If it does get to the bottom, it will pick up the sheet just fine. However, if we stack them high (as they should be), the robot will pick up maybe a couple then slam into the pile and the Servo Tracking Error L & B populates.

    /JOB

    //NAME S1SSPK

    //POS

    ///NPOS 2,0,0,6,0,0

    ///TOOL 0

    ///POSTYPE PULSE

    ///PULSE

    C00000=252316,49442,-37418,0,37939,-41371

    C00001=238349,38429,-33484,0,31177,-36751

    ///TOOL 1

    ///POSTYPE BASE

    ///RECTAN

    ///RCONF 1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0

    P00101=0.000,0.000,100.000,0.0000,0.0000,0.0000

    ///TOOL 0

    ///POSTYPE PULSE

    ///PULSE

    P00120=164210,-31801,-72994,0,12837,-43462

    ///POSTYPE BASE

    ///RECTAN

    P00121=-1414.679,140.000,-145.000,179.9979,0.0002,89.2000

    P00122=-1414.679,140.000,-1045.000,179.9979,0.0002,89.2000

    ///TOOL 1

    P00123=-1414.686,140.001,-695.627,179.9985,0.0001,89.1999

    ///TOOL 0

    P00124=-1414.679,140.000,-145.000,179.9979,0.0002,89.2000

    //INST

    ///DATE 2015/07/11 10:56

    ///ATTR SC,RW

    ///GROUP1 RB1

    ///LVARS 6,1,8,0,0,0,0,0

    NOP

    '%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

    ' PICK SLIP SHEET

    '%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

    ' Store in cube 64 output

    SPEED VJ=27.50 V=275.0

    DIN LB000 SOUT#(120)

    CALL JOB:AUTOHOME IF LB000=0

    ' Slip sheet pick pounce position

    MOVJ P120

    'Turn on picking ss to plc

    DOUT OT#(78) ON

    ' Wait for slip sheet OK

    WHILE IN#(65)=OFF

    RET IF IN#(41)=ON

    RET IF IN#(85)=ON

    ENDWHILE

    '********************************

    ' Set start position

    '********************************

    ' Set start position equal to

    ' end position

    SET P121 P122

    ' Extract current Z value

    GETE LD001 P121 (3)

    ' Add in offset amount

    SET LD001 EXPRESS LD001 + 900000

    ' Store new Z value

    SETE P121 (3) LD001

    '********************************

    ' Set incremental position

    '********************************

    ' Set position equal to zero

    SUB P101 P101

    ' Store Z increment

    SETE P101 (3) 75000

    '********************************

    ' Set depart position

    '********************************

    ' Set depart position equal to

    ' end position

    SET P124 P122

    ' Extract current Z value

    GETE LD001 P124 (3)

    ' Add in offset amount

    SET LD001 EXPRESS LD001 + 900000

    ' Store new Z value

    SETE P124 (3) LD001

    '********************************

    *RETRY

    ' Turn on vacuum

    CALL JOB:VAC_OFF

    ' Turn on solenoid to limit vac

    DOUT OT#(21) ON

    ' Slip sheet start position

    MOVJ P121 PL=1

    ' Turn on vacuum

    CALL JOB:VAC_ON

    DOUT OT#(21) ON

    ' Check for fast search

    IFTHEN IN#(2045)=ON

    ' Move to last found position

    MOVL P123

    ENDIF

    ' Search for slip sheet

    MOVL P122 V=20.0 UNTIL IN#(3)=ON

    SETE P101 (3) 0

    ' Move away

    DOUT OT#(21) OFF

    IMOV P101 V=75.0 PL=0

    ' Store last found position

    GETS PX123 $PX000

    ' Convert last found position

    CNVRT PX123 PX123 BF

    ' Extract current Z value

    GETE LD001 P123 (3)

    ' Add in offset amount

    SET LD001 EXPRESS LD001 + 100000

    ' Store new Z value

    SETE P123 (3) LD001

    SETE P101 (3) 100000

    ' Move away

    IMOV P101 V=50.0 PL=0

    ' Check slip sheet present

    IFTHEN IG#(1)=0

    ' Increment retry count

    ADD LB005 1

    ' Retry 3 times

    IFTHEN LB005<=3

    JUMP *RETRY

    ENDIF

    CALL JOB:CHK4SS

    ENDIF

    'Turn off picking ss to plc

    DOUT OT#(78) OFF

    ' Slip sheet pick depart

    MOVL C00000 V=500.0

    TIMER T=0.50

    MOVL C00001 V=500.0

    ' Check slip sheet present

    CALL JOB:CHK4SS IF IN#(3)=OFF

    ' Set part held

    SET I119 11

    ' Set OK for fast search

    PULSE OT#(2029)

    ' Slip sheet pick pounce position

    MOVJ P120

    ' Check slip sheet present

    CALL JOB:CHK4SS IF IN#(3)=OFF

    END

Advertising from our partners