Wrong measurement when using interrupt

martenH · Oct 21st 2021

I have this program where it measures the tool lenght of a tool attatched to the robot flange. However when I try to measure a tool it has an overshoot of 50mm to the tool lenght. So my tool is 200mm but the measurment is 250mm.... does anyone know why this is happening? explenation of code: at the starting position for the move along the z axis it get the Z location, then it moves down until it hits a button, where it records that location on the z axis, this location is deducted from the first measured location. this measurment gives a 50mm difference.

Code

&ACCESS RVP
&REL 12
&PARAM TEMPLATE = C:\KRC\Roboter\Template\vorgabe
&PARAM EDITMASK = *
DEF Toolsetter_measure8( )
;FOLD INI
  ;FOLD BASISTECH INI
    GLOBAL INTERRUPT DECL 3 WHEN $STOPMESS==TRUE DO IR_STOPM ( )
    INTERRUPT ON 3 
    BAS (#INITMOV,0 )
  ;ENDFOLD (BASISTECH INI)
  ;FOLD USER INI
    ;Make your modifications here

  ;ENDFOLD (USER INI)
;ENDFOLD (INI)
;FOLD PTP HOME  Vel=30 % DEFAULT Tool[1] Base[0];%{PE}%R 8.3.22,%MKUKATPBASIS,%CMOVE,%VPTP,%P 1:PTP, 2:HOME, 3:, 5:30, 7:DEFAULT
$BWDSTART=FALSE
PDAT_ACT=PDEFAULT
FDAT_ACT=FHOME
BAS(#PTP_PARAMS,30)
PTP XHOME 
;ENDFOLD ;Home position ;Home Position
;FOLD PTP P1 Vel=30 % PDAT1 Tool[0] Base[0];%{PE}%R 5.5.31,%MKUKATPBASIS,%CMOVE,%VPTP,%P 1:PTP, 2:P1, 3:, 5:30, 7:PDAT1
$BWDSTART=FALSE
PDAT_ACT=PPDAT1
FDAT_ACT=FP1
BAS(#PTP_PARAMS,30)
PTP XP1 
;ENDFOLD ;Starting location Z axis
ST=$POS_ACT
StartPos=ST.z
INTERRUPT DECL 1 WHEN $IN[1]==TRUE DO TOOLM() ;Declare interrupt 
MOVEZ() ;Start Z axis movement
INTERRUPT OFF 1 ;Turn off interrupt
;FOLD PTP HOME  Vel=30 % DEFAULT Tool[1] Base[0];%{PE}%R 8.3.22,%MKUKATPBASIS,%CMOVE,%VPTP,%P 1:PTP, 2:HOME, 3:, 5:30, 7:DEFAULT
$BWDSTART=FALSE
PDAT_ACT=PDEFAULT
FDAT_ACT=FHOME
BAS(#PTP_PARAMS,30)
PTP XHOME 
;ENDFOLD ;Return to home
$OUT[1]=FALSE ;Deactivate output 1
END
DEF MOVEZ() ;Moving the robot from position 1 to position 2 on the Z axis 
INTERRUPT ON 1 ;Activate interrupt 
;FOLD PTP P3 Vel=30 % PDAT3 Tool[0] Base[0];%{PE}%R 5.5.31,%MKUKATPBASIS,%CMOVE,%VPTP,%P 1:PTP, 2:P3, 3:, 5:30, 7:PDAT3
$BWDSTART=FALSE
PDAT_ACT=PPDAT3
FDAT_ACT=FP3
BAS(#PTP_PARAMS,30)
PTP XP3 
;ENDFOLD ;End location for Z axis
;FOLD WAIT Time= 0.0 sec;%{PE}%R 8.3.22,%MKUKATPBASIS,%CWAIT,%VWAIT,%P 2:0.0
WAIT SEC 0.0
;ENDFOLD ;Wait for interrupt
END
DEF TOOLM() ;Subroutine for toolsetter
INTERRUPT OFF 1 ;Deactivate interrupt
BRAKE ;Stop robotarm movement
Z1=$POS_ACT
ToolLenght_1=ToolCorecction-Z1.Z
$OUT[1]=TRUE ;turn on output 1
;FOLD WAIT Time= 3 sec;%{PE}%R 5.4.33,%MKUKATPBASIS,%CWAIT,%VWAIT,%P 2:3
WAIT SEC 3
;ENDFOLD ;Wait for 3 seconds
RESUME ;Continue program
END

Display More

Code

DEFDAT Toolsetter_measure8
;FOLD EXTERNAL DECLARATIONS;%{PE}%MKUKATPBASIS,%CEXT,%VCOMMON,%P
;FOLD BASISTECH EXT;%{PE}%MKUKATPBASIS,%CEXT,%VEXT,%P
EXT  BAS (BAS_COMMAND  :IN,REAL  :IN )
DECL INT SUCCESS
;ENDFOLD (BASISTECH EXT)
;FOLD USER EXT;%{E}%MKUKATPUSER,%CEXT,%VEXT,%P
;Make here your modifications

;ENDFOLD (USER EXT)
;ENDFOLD (EXTERNAL DECLARATIONS)
DECL E6POS XP1={X 1193.23206,Y 87.6306686,Z 1551.323,A -85.5697632,B 33.723629,C -104.408302,S 6,T 51,E1 0.0,E2 0.0,E3 0.0,E4 0.0,E5 0.0,E6 0.0}
DECL BASIS_SUGG_T LAST_BASIS={POINT1[] "P4                      ",POINT2[] "P4                      ",CP_PARAMS[] "CPDAT0                  ",PTP_PARAMS[] "PDAT5                   ",CONT[] "                        ",CP_VEL[] "2.0                     ",PTP_VEL[] "30                      ",SYNC_PARAMS[] "SYNCDAT                 ",SPL_NAME[] "S0                      "}
DECL FDAT FP1={TOOL_NO 0,BASE_NO 0,IPO_FRAME #BASE,POINT2[] " ",TQ_STATE FALSE}
DECL PDAT PPDAT1={VEL 100.0,ACC 100.0,APO_DIST 100.0}
DECL E6POS XP2={X 1175.51001,Y 66.8519516,Z 1534.073,A -83.5087433,B 33.6255913,C -89.470047,S 6,T 51,E1 0.0,E2 0.0,E3 0.0,E4 0.0,E5 0.0,E6 0.0}
DECL FDAT FP2={TOOL_NO 0,BASE_NO 0,IPO_FRAME #BASE,POINT2[] " ",TQ_STATE FALSE}
DECL PDAT PPDAT2={VEL 100.0,ACC 100.0,APO_DIST 100.0}
DECL E6POS XP3={X 1193.26697,Y 87.6266327,Z -107.409897,A -85.5685577,B 33.716301,C -104.404999,S 6,T 17,E1 0.0,E2 0.0,E3 0.0,E4 0.0,E5 0.0,E6 0.0}
DECL FDAT FP3={TOOL_NO 0,BASE_NO 0,IPO_FRAME #BASE,POINT2[] " ",TQ_STATE FALSE}
DECL PDAT PPDAT3={VEL 100.0,ACC 100.0,APO_DIST 100.0}
DECL PDAT PPDAT4={VEL 100.0,ACC 100.0,APO_DIST 100.0}
DECL E6POS XP4={X 1339.78796,Y -287.258301,Z 1390.67798,A 94.3873367,B -33.7286797,C -75.4515076,S 6,T 51,E1 0.0,E2 0.0,E3 0.0,E4 0.0,E5 0.0,E6 0.0}
DECL FDAT FP4={TOOL_NO 1,BASE_NO 0,IPO_FRAME #BASE,POINT2[] " ",TQ_STATE FALSE}
DECL PDAT PPDAT5={VEL 100.0,ACC 20.0,APO_DIST 100.0}

DECL REAL StartPos= 1551
DECL REAL ToolLenght_1 = 200
DECL REAL ToolCorecction = 1551

ENDDAT

Display More

DenisCa · Oct 21st 2021

Did you check if your ToolCorecction represents Z of previous position ?

Quote from martenH

ToolLenght_1=ToolCorecction-Z1.Z

In TOOLM(), more likely, it must be :

ToolLenght_1=StartPos - Z1.Z

**panic mode** · Oct 21st 2021

that is correct

btw.

the way the code is written:

1. interrupt is active and robot is moving towards P3

2. interrupt is triggered

3. interrupt subprogram is called.

4. interrupt is turned off

5. robot is told to come to a stop

6. Z1 is initialized... using $POS_ACT !?

note that in point 6 (Z1 is initialized), robot position is different from position when interrupt was triggered (point 2).

why use $POS_ACT instead of $POS_INT inside to get value into Z1?

this is exactly why $POS_INT exists. in fact that is the only place one can use $POS_INT or $AXIS_INT - inside the interrupt subroutine. which in your case is TOOLM()

martenH · Oct 22nd 2021

first of all thank you all for the replies. I changed $POS_ACT in toolm() to $POS_INT however im still getting a wrong reading however its now around 30mm. And yess my tool correction is adjusted to the starting possition i measure it once and then leave it in the program. It can be found in my .DAT file

martenH · Oct 22nd 2021

I checked the starting position and ending position and the X and the y possition stay the same so no deviation in the movement

hermann · Oct 22nd 2021

What kind of robot do you have? The measure movement is a PTP movement. With standard Kuka robots you won't get a straight line.

The movement with 30% is way to fast for measuring, try a much slower and a Lin movement.

After getting correct values you can increase the speed.

martenH · Oct 22nd 2021

Im using the following

SPECS:

KRC V5.5.10

GUI version: 2.0.6.6 b65

Kernel system version: KS V5.5.64

Robot:KR16 C2 FLR ZH16

I adjusted the PTP motion to a LIN this morning right now this is the code, But this shouldnt be the problem at the moment..

Code

&ACCESS RVO
&REL 32
&PARAM TEMPLATE = C:\KRC\Roboter\Template\vorgabe
&PARAM EDITMASK = *
DEF Toolsetter_measure11_Loc( )
;FOLD INI
  ;FOLD BASISTECH INI
    GLOBAL INTERRUPT DECL 3 WHEN $STOPMESS==TRUE DO IR_STOPM ( )
    INTERRUPT ON 3 
    BAS (#INITMOV,0 )
  ;ENDFOLD (BASISTECH INI)
  ;FOLD USER INI
    ;Make your modifications here

  ;ENDFOLD (USER INI)
;ENDFOLD (INI)
;FOLD PTP HOME Vel=30 % DEFAULT;%{PE}%R 5.5.31,%MKUKATPBASIS,%CMOVE,%VPTP,%P 1:PTP, 2:HOME, 3:, 5:30, 7:DEFAULT
$BWDSTART=FALSE
PDAT_ACT=PDEFAULT
FDAT_ACT=FHOME
BAS(#PTP_PARAMS,30)
$H_POS=XHOME
PTP XHOME 
;ENDFOLD
;FOLD PTP P1 Vel=30 % PDAT1 Tool[0] Base[0];%{PE}%R 5.5.31,%MKUKATPBASIS,%CMOVE,%VPTP,%P 1:PTP, 2:P1, 3:, 5:30, 7:PDAT1
$BWDSTART=FALSE
PDAT_ACT=PPDAT1
FDAT_ACT=FP1
BAS(#PTP_PARAMS,30)
PTP XP1 
;ENDFOLD
ST=$POS_ACT
StartPos=ST.z
ToolLenght_2Z=ST.z
ToolLenght_2X=ST.x
ToolLenght_2Y=ST.y
INTERRUPT DECL 1 WHEN $IN[1]==TRUE DO TOOLM() ;Declare interrupt 
MOVEZ() ;Start Z axis movement
INTERRUPT OFF 1 ;Turn off interrupt
;FOLD PTP HOME  Vel=30 % DEFAULT Tool[1] Base[0];%{PE}%R 8.3.22,%MKUKATPBASIS,%CMOVE,%VPTP,%P 1:PTP, 2:HOME, 3:, 5:30, 7:DEFAULT
$BWDSTART=FALSE
PDAT_ACT=PDEFAULT
FDAT_ACT=FHOME
BAS(#PTP_PARAMS,30)
PTP XHOME 
;ENDFOLD ;Return to home
$OUT[1]=FALSE ;Deactivate output 1
END
DEF MOVEZ() ;Moving the robot from position 1 to position 2 on the Z axis 
INTERRUPT ON 1 ;Activate interrupt 
;FOLD LIN P3 Vel=2 m/s CPDAT1 Tool[0] Base[0];%{PE}%R 5.5.31,%MKUKATPBASIS,%CMOVE,%VLIN,%P 1:LIN, 2:P3, 3:, 5:2, 7:CPDAT1
$BWDSTART=FALSE
LDAT_ACT=LCPDAT1
FDAT_ACT=FP3
BAS(#CP_PARAMS,2)
LIN XP3 
;ENDFOLD
;FOLD WAIT Time= 0.0 sec;%{PE}%R 8.3.22,%MKUKATPBASIS,%CWAIT,%VWAIT,%P 2:0.0
WAIT SEC 0.0
;ENDFOLD ;Wait for interrupt
END
DEF TOOLM() ;Subroutine for toolsetter
INTERRUPT OFF 1 ;Deactivate interrupt
BRAKE ;Stop robotarm movement
Z1=$POS_INT
ToolLenght_1=ToolCorecction-Z1.z
ToolLenght_1Z=Z1.z
ToolLenght_1X=Z1.x
ToolLenght_1Y=Z1.y
$OUT[1]=TRUE ;turn on output 1
;FOLD WAIT Time= 3 sec;%{PE}%R 5.4.33,%MKUKATPBASIS,%CWAIT,%VWAIT,%P 2:3
WAIT SEC 3
;ENDFOLD ;Wait for 3 seconds
RESUME ;Continue program
END

Display More

hermann · Oct 22nd 2021

What is slow at 2m/s? Try 0.02 m/s.

martenH · Oct 22nd 2021

Changed it to 0.02 m/s and tried it but no change in measurment its still the same measurment

**panic mode** · Oct 22nd 2021

Are the robot motions really correct?

If you tell the robot to move 300mm in some direction, does it really move that exact distance?

If not, check if MADA is is correct and if mastering is correct.

martenH · Oct 22nd 2021

yesss I think the motion is correct I measured the distance it traveld by hand and the distance that is calculated by the robot it self and they match with each other i think it has to do with the xyz location of the TCP, i tried to adjust them through setup>measure>tool>numerical. I feel like the the difference is the edge of the flang to the center but I dont know if those thoughts are correct...

**panic mode** · Oct 22nd 2021

When tool is nullframe, tcp is center of the flange

martenH · Oct 22nd 2021

Yesss i have activated the nullframe as tool for every movement, however I still get a wrong reading.... As shown on the picture it measures 147mm, however that is not the total lenght of the little wooden stick thats only the the leght until the blue line measured from the bottom... so im basically missing like 50mm.... The calculation that im using is: starting position - ending position = toollenght is this the correct way of calculating?

**SkyeFire** · Oct 22nd 2021

All right, let's back up.

Before anything, you have to calibrate all the elements of this system.

Create a high-accuracy TCP manually, preferably with a fine point.
Use that tool to touch your tool-detect button
1. Use very low speed for maximum accuracy
2. Path-to-touch should be perpendicular to the sensor
3. The sensor should be perpendicular to one of the $BASE planes
  1. That is, the path-to-touch should be aligned with the $BASE X, Y, or Z axes
4. Path should be LIN
5. $BASE should be set to the same values as will be used in production
The position at which the calibration TCP activates the button is the location of the button's "trip point" in space

After this, when you touch the button with your production tools, you need to have the production TCP in the same orientation, and move along the same vector. Your TCP Z axis must be aligned as perfectly as possible to the linear motion.

The difference in $POS_INT, between the calibration tool contact, and the production tool contact, should give you a correction factor you need to add to your production tool's Z axis. If your touch-path is aligned with $BASE.Z, then $POS_INT.Z will be the value you want to use. If your button is wall-mounted, though, you might need to align with $BASE.X or .Y, and use $POS_INT.X or .Y accordingly.

It is mathematically possible to do these calculations without aligning the $TOOL, $BASE, and button, but it's much harder and more failure prone. So doing a proper setup initially is key to saving yourself a lot of work, and pain, later on.

DenisCa · Oct 22nd 2021

Try something like on the picture

martenH · Oct 25th 2021

Little update for the people that were invested in this problem. I got the measuring correct now. i created a calibration tool that i use to measure the working area. I takes the starting possition and the end possiton and makes a work area out of these positions, After that i measure a tool, the calculation that follows is the staring position minus traveled distance on the z axis. This value is then subtracted from the working area, this gives me a pretty accurate reading for a test build made out of ducttape and wooden sticks :D. thank you all for you help with solving this problem!

Wrong measurement when using interrupt

Advertising from our partners

How to see your Job Posting (search or recruit) here in Robot-Forum.com

Robotics Technician - Detroit/Ann Arbor area - Radwell International

Share