How to communicate with a EtherCAT device in KRL

chiachingyen · Jun 12th 2021

Spec

KR C4 / KSS V8.3.42 / WorkVisual 6.0

KR300 R2500 with a linear rail(E1)

Stepper Motor: Oriental Motor DGM200 and its EtherCAT-compatible driver AZD-CED

My goal

I want to do hot-wire cutting with the robot, and I need a turntable to rotate the workpiece. I bough a third-party stepper motor with a EtherCAT-enabled driver, trying to make a turntable by myself.

Requirement

I'll do the cutting only when the turntable is stationary, so the motor don't have to work synchronously with the robot axes.

My approach

I add a new Kuka motor as a simulated and asynchronous axis (E2) in WoV, and I plan to map E2 to some sort of KRL/SPS/EtherCAT things to command the external motor to rotate.

What have been done so far

I can jog the motor with the setting software provided the vendor, but it is done by GUI and a USB cable, no EtherCAT thing is involved. Also, the jogging is done on a common laptop, and the robot controller can't interact with it.

I imported the ESI file and add it to the topology, and the motor is wired drive accordingly. Also, the CANopen over EtherCAT is giving me some values. The teach-pendant show no error so far, and the LED light on the motor driver indicates the the EtherCAT communication is "operational".

My next step and question

In this post, Skyefire said

Quote

But assuming you can get a connection, you can send any data over any FieldBus using KRL.

I guess my next step is to find out which KRL syntax to send a message to a EtherCAT device. Then I can start try and error to compose the correct format of operation command.

My question is, am I on the right track? If so, which KRL I should look into? I'm currently looking at CWRITE but its manual doesn't mention anything about field bus, X44, or EtherCAT, nor do the EtherCat Manual for KSS 8.3-8.4 provide any syntax example.

I studied in architecture, having no background knowledge of mechanical or electrical engineering. My approach, my assumption, and my question could be terribly wrong. Any hint that can help me to narrow down things to read and try will be very appreciated.

chiachingyen · Jun 13th 2021

UPDATE

I learned that I have to map the PDO objects to the digital I/O in WoV, and then use SIGNAL to group a series of I/O.

Ben014 · Jun 13th 2021

KUKA Ethercat protocal doesnt support SOE(Servo over Ethercat), if you still want to control your own driver over Ethercat, you have to build your own library. About the mapping in workvisual, it wont allow you edit the PDO(position, speed, acceleration,...), you need to change the xml file of your driver then import to Wov. Furthermore, it might have problem with byte swapping when mapping over 2 bytes, just need to check value received from robot and value shown on the driver manufacturer software.

chiachingyen · Jun 16th 2021

Thank you huythai for your reply,

Somehow I managed to operate the motor with KRL.

Currently, I use lots of SIGNAL, WAIT SEC and WAIT FOR, so the latency add up. But it has fulfilled the requirement I need.

I still have many things to learn, like SOE, PDO, and editing ESI. Once I have sorted these things out, I'll put a simple instruction of how I have done these. Hope that will help newbies like me.

pfuser · Jul 23rd 2021

Quote from chiachingyen

I imported the ESI file and add it to the topology

Hello.

How do you import an ESI file?

I haven't found it yet.

**panic mode** · Jul 23rd 2021

Start WoV without any project open, then use Menu File, Import/Export, device description file, navigate to file you want imported... And if file does not show up, change filter...

pfuser · Jul 23rd 2021

Quote from panic mode

Start WoV without any project open, then use Menu File, Import/Export, device description file, navigate to file you want imported... And if file does not show up, change filter...

You are right.

I forgot to choose a filter.

Thank you.

Nicolas Molina Methfessel · Jun 21st 2022

Quote from chiachingyen

Thank you huythai for your reply,
Somehow I managed to operate the motor with KRL.
Currently, I use lots of SIGNAL, WAIT SEC and WAIT FOR, so the latency add up. But it has fulfilled the requirement I need.

I still have many things to learn, like SOE, PDO, and editing ESI. Once I have sorted these things out, I'll put a simple instruction of how I have done these. Hope that will help newbies like me.

I am beginning to implement the same thing. I have connected 4 JMC Jasd7502 EC Servo drives to a KRC4 robot. They are installed with a working ESI. I can exchange IO between servos and Robot.

These servos will open and close a gripper to variable positions.
I am thinking of writing a KRL file with signals etc... to initialize drive, home, set target position and move.
Did your method work? could you share your KRL file? how bad is the latency?

chiachingyen · Jun 22nd 2022

Quote from Nicolas Molina Methfessel

I am beginning to implement the same thing. I have connected 4 JMC Jasd7502 EC Servo drives to a KRC4 robot. They are installed with a working ESI. I can exchange IO between servos and Robot.
These servos will open and close a gripper to variable positions.
I am thinking of writing a KRL file with signals etc... to initialize drive, home, set target position and move.
Did your method work? could you share your KRL file? how bad is the latency?

Hi Nicolas,

Here is my code,

Code: rotate_turntable.src

&ACCESS RVO1
&COMMENT Rotate the turntable
DEF rotate_turntable (target_pos:IN )

;Declaration
DECL INT target_pos

SIGNAL RxPDO_TARGET_POS $OUT[281] TO $OUT[312] ;32 bit
SIGNAL TB_Set_new_point $OUT[269]

SIGNAL TB_Target_reached $IN[275]
SIGNAL TB_Set_point_ACK $IN[277]

;Reset TB_Set_new_pt if it's not previously set as FALSE
IF TB_Set_new_point==TRUE THEN
    TB_Set_new_point=FALSE
    WAIT FOR NOT ( TB_Set_point_ACK )
ENDIF

;Set the Target position
RxPDO_TARGET_POS = target_pos

;set new point
TB_Set_new_point=TRUE
WAIT FOR ( TB_Set_point_ACK )

;Once the set point is acknowledged, set the TB_Set_new_pt to False
TB_Set_new_point=FALSE
WAIT FOR NOT ( TB_Set_point_ACK )

;Wait until the motor reach the target point
WAIT FOR  (  TB_Target_reached ) 

END

Display More

This script did the job although I haven't refactored it to make it more concise.
I never measure the latency since it's not a time-critical project.

I hope this can be helpful, and any advice is very welcome!

Nicolas Molina Methfessel · Jul 6th 2022

In case this can help someone. I made 3 programs for my servos; Init, move to, reset. and sharing them below. (the program is for 4 servos that comply with Cia402 spec)

PS; did you have a problem with Distributed clock synchronization? Work visual won't build the application if I turn DC-synchron on.

Code: INIT_servo.src

&ACCESS RVP
&COMMENT inicializar servos de pinza
DEF INIT_servos ( RDY :OUT)

;Declaration

DECL BOOL RDY
DECL BOOL RDY1
DECL BOOL RDY2
DECL BOOL RDY3
DECL BOOL RDY4
DECL INT C


SIGNAL speed $IN[100] TO $IN[131] ;32 bit
SIGNAL acc $IN[132] TO $IN[163] ;32 bit
SIGNAL dec $IN[164] TO $IN[195] ;32 bit
SIGNAL speed1 $OUT[356] TO $OUT[387] ;32 bit
SIGNAL acc1 $OUT[388] TO $OUT[419] ;32 bit
SIGNAL dec1 $OUT[420] TO $OUT[451] ;32 bit
SIGNAL speed2 $OUT[556] TO $OUT[587] ;32 bit
SIGNAL acc2 $OUT[588] TO $OUT[619] ;32 bit
SIGNAL dec2 $OUT[620] TO $OUT[651] ;32 bit
SIGNAL speed3 $OUT[756] TO $OUT[787] ;32 bit
SIGNAL acc3 $OUT[788] TO $OUT[819] ;32 bit
SIGNAL dec3 $OUT[820] TO $OUT[851] ;32 bit
SIGNAL speed4 $OUT[956] TO $OUT[987] ;32 bit
SIGNAL acc4 $OUT[988] TO $OUT[1019] ;32 bit
SIGNAL dec4 $OUT[1020] TO $OUT[1051] ;32 bit

RDY=FALSE
RDY1=FALSE
RDY2=FALSE
RDY3=FALSE
RDY4=FALSE
RESET_CMD()
Wait sec 0.5
;servo 1
$OUT[316]=true ;operation mode
$OUT[301]=true ;voltage given
$OUT[302]=true ;quick stop
$OUT[307]=true ;reset fallas

;servo 2
$OUT[516]=true ;operation mode
$OUT[501]=true ;voltage given
$OUT[502]=true ;quick stop
$OUT[507]=true ;reset fallas

;servo 3
$OUT[716]=true ;operation mode
$OUT[701]=true ;voltage given
$OUT[702]=true ;quick stop
$OUT[707]=true ;reset fallas

;servo 4
$OUT[916]=true ;operation mode
$OUT[901]=true ;voltage given
$OUT[902]=true ;quick stop
$OUT[907]=true ;reset fallas

FOR C=1 TO 10 STEP 1 ; 6 loops is enough to get to Ready

    ;servo 1
IF $IN[300] AND NOT $IN[303] THEN
    CONTINUE
    ON_ERROR_PROCEED
    speed1=speed
    acc1=acc
    dec1=dec
    $OUT[300]=true ;startup
    IF $IN[301] THEN
        $OUT[303]=true ;Drive Enable
        IF $IN[302] AND NOT $IN[303] THEN
            RDY1=true
        ENDIF
    ENDIF
ENDIF

    ;servo 2
IF $IN[500] AND NOT $IN[503] THEN
    CONTINUE
    ON_ERROR_PROCEED
    speed2=speed
    acc2=acc
    dec2=dec
    $OUT[500]=true ;startup
    IF $IN[501] THEN
        $OUT[503]=true ;Drive Enable
        IF $IN[502] AND NOT $IN[503] THEN
            RDY2=true
        ENDIF
    ENDIF
ENDIF

    ;servo 3
IF $IN[700] AND NOT $IN[703] THEN
    CONTINUE
    ON_ERROR_PROCEED
    speed3=speed
    acc3=acc
    dec3=dec
    $OUT[700]=true ;startup
    IF $IN[701] THEN
        $OUT[703]=true ;Drive Enable
        IF $IN[702] AND NOT $IN[703] THEN
            RDY3=true
        ENDIF
    ENDIF
ENDIF

    ;servo 4
IF $IN[900] AND NOT $IN[903] THEN
    CONTINUE
    ON_ERROR_PROCEED
    speed4=speed
    acc4=acc
    dec4=dec
    $OUT[900]=true ;startup
    IF $IN[901] THEN
        $OUT[903]=true ;Drive Enable
        IF $IN[902] AND NOT $IN[903] THEN
            RDY4=true
        ENDIF
    ENDIF
ENDIF

IF RDY1 AND RDY2 AND RDY3 AND RDY4 THEN
    $OUT[307]=False ;reset fallas
    $OUT[507]=False ;reset fallas
    $OUT[707]=False ;reset fallas
    $OUT[907]=False ;reset fallas
    RDY=true
    EXIT
ENDIF

ENDFOR

END

Display More

Code: Move_grip.src

&ACCESS RVP
&COMMENT mover pinza
DEF Move_to (moveOK)

;Declaration
DECL BOOL moveOK

SIGNAL Target_posL $IN[196] TO $IN[227] ;32 bit target left gripper 1/1000mm
SIGNAL Target_posR $IN[228] TO $IN[259] ;32 bit target right gripper 1/1000mm
SIGNAL Tpos1 $OUT[324] TO $OUT[355] ;32 bit target servo1 1/1000mm
SIGNAL Tpos2 $OUT[524] TO $OUT[555] ;32 bit target servo2 1/1000mm
SIGNAL Tpos3 $OUT[724] TO $OUT[755] ;32 bit target servo3 1/1000mm
SIGNAL Tpos4 $OUT[924] TO $OUT[955] ;32 bit target servo4 1/1000mm
moveOK=FALSE

Tpos1=Target_posL
Tpos2=-Target_posL
Tpos3=Target_posR
Tpos4=-Target_posR
Wait sec 0.5

CONTINUE
ON_ERROR_PROCEED
$OUT[305]=true ;execute/go to target
CONTINUE
ON_ERROR_PROCEED
$OUT[505]=true ;execute/go to target
CONTINUE
ON_ERROR_PROCEED
$OUT[705]=true ;execute/go to target
CONTINUE
ON_ERROR_PROCEED
$OUT[905]=true ;execute/go to target

LOOP
    if $in[313] THEN
        $out[260]=true ;servo1 moving
    ENDIF
    if $in[513] THEN
        $out[261]=true ;servo2 moving
    ENDIF
    if $in[713] THEN
        $out[262]=true ;servo3 moving
    ENDIF
    if $in[913] THEN
        $out[263]=true ;servo4 moving
    ENDIF
    IF $IN[311] AND $IN[511] AND $IN[711] AND $IN[911] AND not $in[313]AND not $in[513]AND not $in[713]AND not $in[913] THEN
        $OUT[305]=False ;execute/go to target
        $out[260]=FALSE ;servo1 moving
        $OUT[505]=False ;execute/go to target
        $out[261]=FALSE ;servo1 moving
        $OUT[705]=False ;execute/go to target
        $out[262]=FALSE ;servo1 moving
        $OUT[905]=False ;execute/go to target
        $out[263]=FALSE ;servo1 moving
        moveOK=True
        EXIT
    ENDIF
ENDLOOP

END

Display More

Code: RESET_CMD.src

&ACCESS RVP
&COMMENT reset comand word
DEF RESET_CMD()

SIGNAL CMD1 $OUT[300] TO $OUT[315] ;16 bit command word servo1
SIGNAL Mode1 $OUT[316] TO $OUT[323] ;8 bit control mode servo1
SIGNAL CMD2 $OUT[500] TO $OUT[515] ;16 bit command word servo1
SIGNAL Mode2 $OUT[516] TO $OUT[523] ;8 bit control mode servo1
SIGNAL CMD3 $OUT[700] TO $OUT[715] ;16 bit command word servo1
SIGNAL Mode3 $OUT[716] TO $OUT[723] ;8 bit control mode servo1
SIGNAL CMD4 $OUT[900] TO $OUT[915] ;16 bit command word servo1
SIGNAL Mode4 $OUT[916] TO $OUT[923] ;8 bit control mode servo1

CONTINUE
ON_ERROR_PROCEED
CMD1=0
CONTINUE
ON_ERROR_PROCEED
Mode1=0
CONTINUE
ON_ERROR_PROCEED
CMD2=0
CONTINUE
ON_ERROR_PROCEED
Mode2=0
CONTINUE
ON_ERROR_PROCEED
CMD3=0
CONTINUE
ON_ERROR_PROCEED
Mode3=0
CONTINUE
ON_ERROR_PROCEED
CMD4=0
CONTINUE
ON_ERROR_PROCEED
Mode4=0

END

Display More

How to communicate with a EtherCAT device in KRL

Spec

My goal

Requirement

My approach

What have been done so far

My next step and question

Nation Jun 12th 2021

Create an account or sign in to comment

How to see your Job Posting (search or recruit) here in Robot-Forum.com

Share

Tags

Users Viewing This Thread