Countdown timer that runs in the background

xerim · Apr 22nd 2021

Hello,

I've put together this small program that counts down from a given amount of seconds and I would like it to display on the FlexPendant while the robot is running to let the operator know when the program will end. Because the cycle time is the same, this solution works as I can simply input the cycle time in seconds and have it count down from there. I am trying to get this program to run in the background because when you put in in the main program it always hangs on "WaitTime currentTimeStep" which makes sense, because it is an instruction telling the robot to wait. How can I get this program to run in the background so it doesn't get in the way of the main program?

Code

MODULE WaitTimeModule
CONST num timeStep:=1;
  
 PROC RemainingTime(num waitingTime)
  VAR num currentTimeStep;
  VAR num timeLeft:=0;
  VAR string displayString;
  


 
  timeLeft:=waitingTime;

  WHILE timeLeft>0 DO
   IF timeLeft<timeStep THEN
    currentTimeStep:=timeLeft;   
    timeLeft:=0;
   ELSE
    Add timeLeft,-timeStep;
    currentTimeStep:=timeStep;
   ENDIF
   TPErase;
   TPWrite "Time Remaining is:" + SecondstoTime(timeLeft);
   WaitTime currentTimeStep;
  ENDWHILE

 ENDPROC
 
 
 FUNC string SecondstoTime(num s)
VAR num seconds:=0;
VAR num minutes:=0;
VAR num hours:=0;

     s:=Round(s);
     seconds:=0;
     minutes:=0;
     hours:=0;
     
     IF s>=60 THEN
         minutes:= s DIV 60;
         seconds:= s MOD 60;
     ELSE
         seconds:=s;
     ENDIF
     minutes:=Trunc(minutes);
     
     IF minutes >= 60 THEN
        hours:= minutes DIV 60;
        minutes:= minutes MOD 60;
     ELSE
         minutes:=minutes;
     ENDIF
RETURN NumToStr(hours,0) + "hr" +  NumToStr(minutes,0) + "m" + NumToStr(seconds,0) + "s";
 ENDFUNC

     

 PROC main()
RemainingTime 11400;
 ENDPROC
ENDMODULE

Display More

**SkyeFire** · Apr 22nd 2021

This sounds like a good job for a background task, the creation of which I had to get some help on back in 2019: RE: Create a new Task from scratch

That said, I've never tried writing user messages from a background task -- I'm honestly not sure if that would create a "custody conflict" or not. Worth trying, though.

xerim · Apr 22nd 2021

I tried changing the module to SEMISTATIC by editing the controller section of the configuration editor, but then when I press pp to main it says there is not an active program pointer..I know the controller can run tasks in the background because there is already a task in there that is checking for errors while the robot is running. Perhaps I have too many background tasks now..

**SkyeFire** · Apr 23rd 2021

Well, you could just add your Timer code to the existing background task, maybe as a new PROC. As long as you program it without any Wait commands, it shouldn't disrupt the existing task.

I don't recall exactly, and don't have an ABB to try it on, but I'm not sure "SemiStatic" is the correct setting. Once I had it working, this is what the entry in BACKINFO.TXT looked like when I took a backup:

Code

>>TASK3: (Background,,)
SYSMOD/user.sys @ 
PROGMOD/MainModule.mod @

Task 3 was my background Task, and I literally just named it "Background."

USER.SYS was an empty file auto-created by the robot when I created Task 3.

Pretty sure most ABBs can handle multiple background tasks... I think the original IRC5s could handle 5 or 8 running in parallel.

This is the background task module I created that I mentioned before. It's literally a completely ordinary RAPID module, it's just the Task that is set to Background. As you can see, I only put subroutine calls in the Main, making it easy to add/subtract subroutines for future edits. No Waits, to ensure no subroutine blocks another. No loops, b/c a Background Task loops inherently (basically, it keeps calling Main over and over).

Code

MODULE MainModule
    PERS num PulseCount:=0;
    PERS num PulseMemory:=0;

    PROC main()
        CountShaftRotationPulses;
        GripperStatusOutputToPLC;
    ENDPROC

    !*** Count camshaft rotations whenever Gripper Motor is running ***
    PROC CountShaftRotationPulses()
        ! if running shaft-spinning motor, count
        IF ((doGr1_MtrCCW=1) OR (doGr1_MtrCw=1)) THEN
            IF (PulseMemory<>diGr1Spinning) THEN
                PulseMemory:=diGr1Spinning;
                Incr PulseCount;
            ENDIF
            SetGO goPulseCount,PulseCount;
            ! update virtual output accessible by foreground task
        ELSE
            PulseCount:=0;
        ENDIF

        !insurance against counter overflow
        IF (PulseCount>1000000) PulseCount:=0;
    ENDPROC

    !Outputs gripper status to the PLC
    PROC GripperStatusOutputToPLC()

        IF (diGr1_Opend=1) set doGr1_Open_PLC;
        IF (diGr1_Clsd=1) set doGR1_Close_PLC;
        IF (diShaftInGr1=1) set doShaftInGr1_PLC;
        IF (diGr1_Opend=0) reset doGr1_Open_PLC;
        IF (diGr1_Clsd=0) reset doGR1_Close_PLC;
        IF (diShaftInGr1=0) reset doShaftInGr1_PLC;
    ENDPROC

ENDMODULE

Display More

xerim · Apr 23rd 2021

Quote from SkyeFire

As long as you program it without any Wait commands, it shouldn't disrupt the existing task.

I think that is my main problem, my program to count time relies on line 24 of the code I posted above (WaitTime currentTimeStep;) I'm going to have to find another solution, thanks for your help

**SkyeFire** · Apr 23rd 2021

I haven't tried this in a background task, but CTime() should allow you to check the time, then do some math on it. This is an old program that autosaved certain files once a day, but it was part of the foreground task, not a background.

(the FileTime variables are leftover from when I attempted to check the age of the existing backup file, and base the Save on that. But I was never able to get the age to parse correctly from Unix Epoch to a date/time that I could compare against CTime and CDate)

Code

  PROC AutoSave()
  
  ! Checks the current date against the last time the module in //filevault/application/custom/modules was saved,
  ! and saves fresh copies of all Unracking-related RAPID modules if the saved copies are too old.
    
    VAR NUM    Today_in_Seconds;
    VAR NUM    Current_Seconds;
    VAR NUM    Current_Filetime;
    VAR NUM    Module_Filetime;
    VAR STRING Todays_Date;
    VAR STRING Todays_Time;
    VAR BOOL   Convert_Success;
    VAR NUM    Year;
    VAR NUM    Month;
    VAR NUM    Day;

    Date_Check:    
    Todays_Time:=Ctime();
    Todays_Date:=CDate();
    Module_Filetime:=FileTime("//filevault/application/custom/modules/custom3.mod"\ModifyTime);

    ! converts the sections of the CDate string into numbers for Year, Month, Day    
    Convert_Success:=StrToVal (StrPart(Todays_Date,1,4),Year);
    Convert_Success:=StrToVal (StrPart(Todays_Date,6,2),Month);
    Convert_Success:=StrToVal (StrPart(Todays_Date,9,2),Day);    

    IF ((OpMode()<>OP_AUTO) OR (Day<>Last_Autosave)) THEN
      
      TPErase;
      TPWrite "AutoSave of RT_ENG_UNRACK Module to";
      TPWrite "//FVault/App/Custom/Modules/Custom3.mod";
      TPWrite " ";
      Save "RT_ENG_UNRACK" \FilePath:="//filevault/application/custom/modules/custom3.mod";
      TPWrite "AutoSave of ISRA_Calibration to";
      TPWrite "//FVault/App/Custom/Modules/Custom2.mod";
      TPWrite " ";
      Save "ISRA_Calibration" \FilePath:="//filevault/application/custom/modules/custom2.mod";
      TPWrite "AutoSave of ISRA_Vision to";
      TPWrite "//FVault/App/Custom/Modules/Custom1.sys";
      Save "ISRA_Vision" \FilePath:="//filevault/application/custom/modules/custom1.sys";
      Last_Autosave:=Day;
    ENDIF
    
    RETURN;
  
  ENDPROC

Display More

xerim · Apr 23rd 2021

Good idea, I have actually been working on this in a different direction now by using CTime() to output the current time + the duration of the cycle as opposed to constantly updating the remaining duration. The plan is to convert the output from CTime() to seconds, add it to the duration (in seconds) and then use a function to convert total seconds to a time format.

Countdown timer that runs in the background

Advertising from our partners

How to see your Job Posting (search or recruit) here in Robot-Forum.com

Robotics Technician - Detroit/Ann Arbor area - Radwell International

Share