Debugging EKI Error: Access to empty elementmemory

impartialist · Dec 1st 2020

I'm trying to communicate between a Linux PC and KRC4, sending xml via EKI.

I can get a message from KUKA > Linux no problem, but struggle with the other way around.

In the code below, I hit the line RET=EKI_GetReal("XmlTransmit","Robot/Axis/Speed",valueSpeed) and get the error "Access to empty elementmemory"

Are there any debugging things I can do? How can I check the XML packet has been sent/received?

Thanks!

Code

;FOLD Declaration


DECL REAL SPEED
DECL EKI_STATUS RET
REAL valueSpeed


CHAR sendBytes[4]


;ENDFOLD (Declaration)




;-- We expect the sent and received data to look something like the below


;FOLD Communicated data
;------------------------------------------
; Data transmitted: binary version -  cast int array to bytes[4] array


; Data transmitted: (XML version)
; <Robot>
; <Data>
; <LineNum>1234
; </LineNum>
; </Data>
; </Robot>


;--------------------
; Data received:
; <Robot>
; <Axis>
; <Speed>25.0 </Speed>
; </Axis>
; </Robot>
;-------------------------------------------
;ENDFOLD (Communicated data)


;-- Initialisation
;FOLD INI;%{PE}
;FOLD BASISTECH INI
GLOBAL INTERRUPT DECL 3 WHEN $STOPMESS==TRUE DO IR_STOPM ( )
INTERRUPT ON 3
BAS (#INITMOV,0 )
;ENDFOLD (BASISTECH INI)
;FOLD USER INI
;Make your modifications here
;ENDFOLD (USER INI)
;ENDFOLD (INI)ENDEND


;FOLD Initialize data
valueSpeed = 0.0
;ENDFOLD (Initialize data)


;-- Open connection and send/receive data


RET=EKI_Init("XmlTransmit")
RET=EKI_Open("XmlTransmit")




;FOLD Write data to connection


; Binary version:
sendBytes[1] = 1
sendBytes[2] = 2
sendBytes[3] = 3
sendBytes[4] = 6


RET=EKI_Send("XmlTransmit",sendBytes[])


;ENDFOLD (Write data to connection)


;-------------------------------------------
;FOLD Get received sensor data
; Get real value in <Speed = "" />
RET=EKI_GetReal("XmlTransmit","Robot/Axis/Speed",valueSpeed)
SPEED = valueSpeed


;-- Do something with SPEED!




;ENDFOLD (Get received sensor data)
RET=EKI_Close("XmlTransmit")
RET=EKI_Clear("XmlTransmit")

Display More

impartialist · Dec 1st 2020

I think I found the issue... I put a WAIT command before the problematic line and it worked...!

The question still stands though, is there an easy way to debug this, or to catch if I've requested info that isn't yet available?

panic mode · Dec 1st 2020

you are reading blindly.... without checking if anything was received. or if received message contains value for "Robot/Axis/Speed"

Mentat · Dec 1st 2020

For networking problems Wireshark is indispensable.

Are you sure you defined Robot/Axis/Speed in XmlTransmit.xml correctly? Also, shouldn't it be waiting for flag to read?

impartialist · Dec 1st 2020

Thanks for the reply. Totally beginner to this - going off examples.

What's the best practice for checking something was received? I've just been toying with ON_ERROR_PROCEED in case nothing was yet received, but that doesn't feel right.

panic mode · Dec 1st 2020

examples show how to do this.... they use interrupt to sense flag when message is received

but you don't have to use an interrupt... it is possible to utilize WAIT as you already did.

the key part is to format XML configuration to tell you when message is received. for example here we use $FLAG[998]

Code

<RECEIVE>
    <XML>
        <ELEMENT Tag="ToKRC/Command" Type="STRING"/>   <!-- data -->            
        <ELEMENT Tag="ToKRC/SpeedLimit" Type="INT"/>   <!-- data -->    
        <ELEMENT Tag="ToKRC/Abort" Type="BOOL"/>       <!-- data -->    
        <ELEMENT Tag="ToKRC" Set_Flag="998"/>          <!-- set $FLAG[998] when data received -->
    </XML>
</RECEIVE>

then in your program you can use

WAIT FOR $FLAG[998]

instead of some arbitrary time.

or you could also make it a bit more complex, for example check if response arrived within some time window.;

Code

; wait for response 
WAIT FOR $FLAG[998] OR TIMER_LIMIT(4.565); wait until we receive something, but no longer than 4.56 sec.

; process response 
IF $FLAG[998] THEN
  $FLAG[998]=FALSE; we got the data, clear flag so we can be notified about next message...
  RET=EKI_GetString("XmlTransmit",ToKRC/Command",ToKRC_Command[]))
  RET=EKI_GetInt("XmlTransmit","ToKRC/SpeedLimit",ToKRC_SpeedLimit)
  RET=EKI_GetBool("XmlTransmit","ToKRC/Abort",ToKRC_Abort)
ELSE
   MsgNotify("Nothing received in 4.56 seconds...")
   ToKRC_Abort=TRUE
ENDIF

Display More

if you are transmitting continuously, make sure to reset that flag. otherwise you will not know when the net message is received.

the other thing that can be done is use CHECK_BUFFER() and read while something is in the receive buffer, and skip if nothing there

impartialist · Dec 11th 2020

Thanks for your help on this. It's all working well!

impartialist · Jan 13th 2021

I've come back to this to add a timeout.
panic mode - I've used timers in a different way before ($TIMER_STOP[19] = FALSE etc). Your method looked much more elegant, but could find any documentation, and I got errors when using WAIT FOR TIMER_LIMIT[4.565]

The error was either ARRAY VARIABLE NOT DECLARED (if an integer), or EXPRESSION NOT EQUAL TO INT (if a float).

Am I missing something?

Mentat · Jan 13th 2021

Timer_limit() is a function, you need to use parentheses instead of square brackets. The parameter is time in seconds.

panic mode · Jan 13th 2021

as Mentat mentioned this is a function, i fixed the typo

Debugging EKI Error: Access to empty elementmemory

Create an account or sign in to comment

Share

Tags