KAREL programming FANUC

Kawazaki02 · September 29, 2020 at 5:18 PM

Hello. need help. I want to move the extended axes of the robot. Has anyone encountered this problem before?

shown in code for 6 axes

PROGRAM TEST_KAREL

%ENVIRONMENT TPE

%ENVIRONMENT BYNAM

CONST

MAX_AXS = 9

JNT_POS = 9

XYZ_POS = 2

VAR

to_prog: STRING[27]

open_id: INTEGER

status: INTEGER

position_no: INTEGER

new_xyz: XYZWPREXT

org_xyz: XYZWPREXT

num_axs: INTEGER

BEGIN

to_prog = 'TEST_TP_1'

OPEN_TPE (to_prog, TPE_RWACC, TPE_RDREJ, open_id, status)

position_no = 3

org_xyz = GET_POS_TPE (open_id, position_no, posn_typ, num_axs, status)

FOR indx_axs= 1 TO num_axs DO

jp_new [indx_axs] = jp_org[indx_axs] + jp_off [indx_axs]

new_xyz.x = org_xyz.x +10

new_xyz.y = org_xyz.y + 10

new_xyz.z = org_xyz.z + 10

new_xyz.w = org_xyz.w + 10

new_xyz.p = org_xyz.p + 10

new_xyz.r = org_xyz.r + 10

SET_POS_TPE (open_id, position_no, new_xyz, status)

CLOSE_TPE (open_id, status)

END TEST_KAREL

hermann · September 29, 2020 at 6:14 PM

Who wrote the program in the picture?

It should be possible to use

Code

new_xyz.ext1=org_xyz.ext1+10

And by the way, you shouldn't post a picture of a program code. Always post the code in some ASCII representation. Nobody here wants to type already existing code by looking onto a picture.

Kawazaki02 · September 29, 2020 at 6:44 PM

Quote from hermann
Кто написал программу на картинке?
Должна быть возможность использовать
Code
new_xyz.ext1 = org_xyz.ext1 + 10
И, кстати, не стоит размещать картинку программного кода. Всегда размещайте код в каком-либо представлении ASCII. Здесь никто не хочет набирать уже существующий код, глядя на картинку.

tried it according to yours, as you need to indicate that this code is for extended axes

Kawazaki02 · September 29, 2020 at 6:53 PM

PROGRAM TEST_KAREL

%ENVIRONMENT TPE

%ENVIRONMENT BYNAM

CONST

MAX_AXS = 9

JNT_POS = 9

XYZ_POS = 2

VAR

to_prog: STRING[25]

open_id: INTEGER

status: INTEGER

position_no: INTEGER

jp_org : ARRAY [9] OF REAL

jp_new : ARRAY [9] OF REAL

prg_select: INTEGER

arr_size : INTEGER

indx : INTEGER

indx_pos: INTEGER

num_pos : INTEGER

indx_axs: INTEGER

num_axs : INTEGER

pos_typ : INTEGER

group_no: INTEGER

org_jpos : JOINTPOS

new_jpos : JOINTPOS

posn_type: INTEGER

org_xyz : XYZWPREXT

new_xyz : XYZWPREXT

BEGIN

to_prog = 'TEST_TP_1'

OPEN_TPE (to_prog, TPE_RWACC, TPE_RDREJ, open_id, status)

group_no = 1

position_no = 3

GET_POS_TYP (open_id, indx_pos, group_no, posn_type, num_axs, status)

WRITE ('get_pos_typ status', status,CR)

SELECT pos_typ OF

CASE (JNT_POS):

SET_JPOS_TPE (open_id, indx_pos, new_jpos, status)

WRITE ('indx_pos', indx_pos, 'new_jpos',CR, new_jpos,CR)

ENDSELECT

org_jpos = GET_JPOS_TPE (open_id, indx_pos, status)

org_xyz = GET_POS_TPE (open_id , indx_pos, status)

new_xyz.x = org_xyz.x +10

new_xyz.y = org_xyz.y +0

new_xyz.z = org_xyz.z +0

new_xyz.w = org_xyz.w +0

new_xyz.p = org_xyz.p +0

new_xyz.r = org_xyz.r +0

new_xyz_ext1 = org_xyz_ext1 + 10

new_xyz_ext2 = org_xyz_ext2 + 10

new_xyz_ext3 = org_xyz_ext3 + 10

SET_POS_TPE (open_id, position_no, new_xyz, status)

CLOSE_TPE (open_id, status)

END TEST_KAREL

Build error

Translating D:\NikolaevAS\Desktop\untitled18.kl

KTRANS Version V8.30 (Build 30 11/12/2019)

Copyright (C) FANUC America Corporation, 1985 through 2016.

D:\NikolaevAS\Desktop\untitled18.kl(72)

72 new_xyz_ext1 = org_xyz_ext1 + 10

^ ERROR

Id must be defined before this use. Id: ORG_XYZ_EXT1

D:\NikolaevAS\Desktop\untitled18.kl(73)

73 new_xyz_ext2 = org_xyz_ext2 + 10

^ ERROR

Id must be defined before this use. Id: ORG_XYZ_EXT2

D:\NikolaevAS\Desktop\untitled18.kl(74)

74 new_xyz_ext3 = org_xyz_ext3 + 10

^ ERROR

Id must be defined before this use. Id: ORG_XYZ_EXT3

D:\NikolaevAS\Desktop\untitled18.kl(76)

76 SET_POS_TPE (open_id, position_no, new_xyz, status)

^ WARNING

Argument will be passed by value. Id: NEW_XYZ

===============Translation not successful===============

Build Failed: Error translating program: Code: 0xFFFFFFFF:

DaveP · September 29, 2020 at 8:11 PM

try replacing the underscores with periods in your new code that Hermann suggested using. His code uses a . instead of a _ in the variable name for the extended axis. new_xyz.ext1 = org_xyz.ext1 + 10

R47 · September 29, 2020 at 9:29 PM

hi kawazaki02,

i think you Need to add %ENVIRONMENT REGOPE on your Code.

Kawazaki02 · September 29, 2020 at 10:06 PM

Quote from DaveP

try replacing the underscores with periods in your new code that Hermann suggested using. His code uses a . instead of a _ in the variable name for the extended axis. new_xyz.ext1 = org_xyz.ext1 + 10

tried it. The result is the same

Kawazaki02 · September 29, 2020 at 10:09 PM

Quote from R47

hi kawazaki02,
i think you Need to add %ENVIRONMENT REGOPE on your Code.

did not work. I don't know what to do anymore

PROGRAM TEST_KAREL

%ENVIRONMENT TPE

%ENVIRONMENT BYNAM

%ENVIRONMENT REGOPE

CONST

MAX_AXS = 9

JNT_POS = 9

XYZ_POS = 2

VAR

to_prog: STRING[25]

open_id: INTEGER

status: INTEGER

position_no: INTEGER

jp_org : ARRAY [9] OF REAL

jp_new : ARRAY [9] OF REAL

prg_select: INTEGER

arr_size : INTEGER

indx : INTEGER

indx_pos: INTEGER

num_pos : INTEGER

indx_axs: INTEGER

num_axs : INTEGER

pos_typ : INTEGER

group_no: INTEGER

org_jpos : JOINTPOS

new_jpos : JOINTPOS

posn_type: INTEGER

org_xyz : XYZWPREXT

new_xyz : XYZWPREXT

org_xyz_ext : XYZWPREXT

new_xyz_ext : XYZWPREXT

BEGIN

to_prog = 'TEST_TP_1'

OPEN_TPE (to_prog, TPE_RWACC, TPE_RDREJ, open_id, status)

group_no = 1

position_no = 3

GET_POS_TYP (open_id, indx_pos, group_no, posn_type, num_axs, status)

WRITE ('get_pos_typ status', status,CR)

SELECT pos_typ OF

CASE (JNT_POS):

SET_JPOS_TPE (open_id, indx_pos, new_jpos, status)

WRITE ('indx_pos', indx_pos, 'new_jpos',CR, new_jpos,CR)

ENDSELECT

org_jpos = GET_JPOS_TPE (open_id, indx_pos, status)

org_xyz = GET_POS_TPE (open_id , indx_pos, status)

new_xyz.x = org_xyz.x +10

new_xyz.y = org_xyz.y +0

new_xyz.z = org_xyz.z +0

new_xyz.w = org_xyz.w +0

new_xyz.p = org_xyz.p +0

new_xyz.r = org_xyz.r +0

new_xyz_ext1 = org_xyz_ext1 + 10

SET_POS_TPE (open_id, position_no, new_xyz, status)

CLOSE_TPE (open_id, status)

END TEST_KAREL

----------------------------------------------------------------------

Translating D:\NikolaevAS\Desktop\untitled18.kl

KTRANS Version V8.30 (Build 30 11/12/2019)

D:\NikolaevAS\Desktop\untitled18.kl(77)

77 new_xyz_ext1 = org_xyz_ext1 + 10

^ ERROR

Id must be defined before this use. Id: ORG_XYZ_EXT1

D:\NikolaevAS\Desktop\untitled18.kl(79)

79 SET_POS_TPE (open_id, position_no, new_xyz, status)

^ WARNING

Argument will be passed by value. Id: NEW_XYZ

===============Translation not successful===============

Build Failed: Error translating program: Code: 0xFFFFFFFF:

----------------------------------------------------------------------

hermann · September 29, 2020 at 10:46 PM

Are you kidding us?

You only had to mark the code in my post and copy it to your .kl file and it would have been worked. That's the reason why code has to be inserted into a code-tag.

Here is the proof, (I have a newer compiler, may be that's the problem, but I don't think so):

Code

PROGRAM TEST_KAREL
%ENVIRONMENT TPE
%ENVIRONMENT BYNAM

CONST
MAX_AXS = 9
JNT_POS = 9
XYZ_POS = 2

VAR
to_prog: STRING[25]
open_id: INTEGER
status: INTEGER
position_no: INTEGER

jp_org : ARRAY [9] OF REAL
jp_new : ARRAY [9] OF REAL
prg_select: INTEGER
arr_size : INTEGER
indx : INTEGER
indx_pos: INTEGER
num_pos : INTEGER
indx_axs: INTEGER
num_axs : INTEGER
pos_typ : INTEGER
group_no: INTEGER
org_jpos : JOINTPOS
new_jpos : JOINTPOS
posn_type: INTEGER
org_xyz : XYZWPREXT
new_xyz : XYZWPREXT

BEGIN
to_prog = 'TEST_TP_1'
OPEN_TPE (to_prog, TPE_RWACC, TPE_RDREJ, open_id, status)
group_no = 1
position_no = 3
GET_POS_TYP (open_id, indx_pos, group_no, posn_type, num_axs, status)
WRITE ('get_pos_typ status', status,CR)
SELECT pos_typ OF
CASE (JNT_POS):
SET_JPOS_TPE (open_id, indx_pos, new_jpos, status)
WRITE ('indx_pos', indx_pos, 'new_jpos',CR, new_jpos,CR)
ENDSELECT

org_jpos = GET_JPOS_TPE (open_id, indx_pos, status)
org_xyz = GET_POS_TPE (open_id , indx_pos, status)
new_xyz.x = org_xyz.x +10
new_xyz.y = org_xyz.y +0
new_xyz.z = org_xyz.z +0
new_xyz.w = org_xyz.w +0
new_xyz.p = org_xyz.p +0
new_xyz.r = org_xyz.r +0
new_xyz.ext1 = org_xyz.ext1 + 10

SET_POS_TPE (open_id, position_no, new_xyz, status)
CLOSE_TPE (open_id, status)

END TEST_KAREL

Display More

Result of Compiling:

----------------------------------------------------------------------

Translating D:\......\test_karel.kl

KTRANS Version V9.10 (Build 17 9/18/2019)

D:\.....\test_karel.kl(56)

56 SET_POS_TPE (open_id, position_no, new_xyz, status)

^ WARNING

Argument will be passed by value. Id: NEW_XYZ

*** Translation successful, 698 bytes of p-code generated, checksum 12310. ***

----------------------------------------------------------------------

Kawazaki02 · September 29, 2020 at 10:54 PM

Quote from hermann

Are you kidding us?
You only had to mark the code in my post and copy it to your .kl file and it would have been worked. That's the reason why code has to be inserted into a code-tag.
Here is the proof, (I have a newer compiler, may be that's the problem, but I don't think so):

thanks, I also compiled, but the additional axes did not move

TomTom · September 30, 2020 at 12:12 PM

After each command always check the status variable. It tells you if the command actually worked or not. For example:

Code

      OPEN_TPE (to_prog, TPE_RWACC, TPE_RDREJ, open_id, status)
      IF (status<>0)  THEN
        FORCE_SPMENU (TP_PANEL, SPI_TPUSER, 1)
        WRITE('Error while opening tp prog',CR)
        POST_ERR(status, '', 0, 2) --2 indicates ABORT; see Karel Manual
        ABORT
      ENDIF

Kawazaki02 · September 30, 2020 at 6:00 PM

Does anyone have an example of a Karel program for shifting additional axes on FANUC robots?

Or consult on this issue.

hermann · October 1, 2020 at 4:11 PM

The program has many issues, and in the first version it does'nt make real sense. Who wrote that?

It compiles, but it has runtime errors and doesn't run till end.

Here is a working one (only tested with one extended axis), BUT: there seems to be an issue in the KAREL system of fanuc. At least in my test equipment the value of extended axis 1 that comes from the funtion GET_POS_TPE has nothing to do with the real value.

Code

PROGRAM TEST_KAREL
%ENVIRONMENT TPE
%ENVIRONMENT BYNAM
%INCLUDE klevtpe

CONST
MAX_AXS = 9


VAR
to_prog: STRING[25]
open_id: INTEGER
status: INTEGER
position_no: INTEGER

jp_org : ARRAY [9] OF REAL
jp_new : ARRAY [9] OF REAL
prg_select: INTEGER
arr_size : INTEGER
indx : INTEGER
indx_pos: INTEGER
num_pos : INTEGER
indx_axs: INTEGER
num_axs : INTEGER
pos_typ : INTEGER
group_no: INTEGER
org_jpos : JOINTPOS
new_jpos : JOINTPOS
posn_type: INTEGER
org_xyz : XYZWPREXT
new_xyz : XYZWPREXT

BEGIN
 to_prog = 'TEST_TP_1'
 OPEN_TPE (to_prog, TPE_RWACC, TPE_RDREJ, open_id, status)
 group_no = 1
 position_no = 3
 indx_pos=3
 GET_POS_TYP (open_id, indx_pos, group_no, posn_type, num_axs, status)
 --WRITE TPDISPLAY(CHR(cc_clear_win),CHR(cc_home)) -- Clear USER screen
 WRITE TPDISPLAY('get_pos_typ status', status,'  ',posn_type,CR)

SELECT posn_type OF
 CASE (pt_jointpos):
  org_jpos = GET_JPOS_TPE (open_id, indx_pos, status)
  new_jpos=org_jpos
  SET_JPOS_TPE (open_id, indx_pos, new_jpos, status)
  WRITE TPDISPLAY('indx_pos', indx_pos, 'new_jpos',CR, new_jpos,CR)   

 CASE (pt_xyzwpr):
  org_xyz = GET_POS_TPE (open_id , indx_pos, status)
  new_xyz=org_xyz
  new_xyz.x = org_xyz.x +10
  new_xyz.y = org_xyz.y +0
  new_xyz.z = org_xyz.z +0
  new_xyz.w = org_xyz.w +0
  new_xyz.p = org_xyz.p +0
  new_xyz.r = org_xyz.r +0 

 SET_POS_TPE (open_id, position_no, new_xyz, status)

 CASE (pt_rxyzwpr):
  org_xyz = GET_POS_TPE (open_id , indx_pos, status)
  new_xyz = org_xyz  -- init values of Configuraion data 
  new_xyz.x = org_xyz.x +10
  new_xyz.y = org_xyz.y +0
  new_xyz.z = org_xyz.z +0
  new_xyz.w = org_xyz.w +0
  new_xyz.p = org_xyz.p +0
  new_xyz.r = org_xyz.r +0
  new_xyz.ext1 = org_xyz.ext1 +10
  -- new_xyz.ext1 = org_xyz.ext1
  WRITE TPDISPLAY('org_xyz', org_xyz,CR)
  WRITE TPDISPLAY('org_xyz.ext1', org_xyz.ext1,CR)
  WRITE TPDISPLAY('org_xyz.ext2', org_xyz.ext2,CR)
  WRITE TPDISPLAY('org_xyz.ext3', org_xyz.ext3,CR)
  WRITE TPDISPLAY('new_xyz', new_xyz,CR)
  SET_EPOS_TPE (open_id, position_no, new_xyz, status)
ENDSELECT

CLOSE_TPE (open_id, status)

END TEST_KAREL

Display More

You can see the outputs of the WRITE statements on the User screen (MENU - 9 USER).

And one more remark: Try to write programs on your own, read the karel manuals, learn to debug programs. jm2c.

I'm out now.

Kawazaki02 · October 1, 2020 at 5:30 PM

Quote from hermann

The program has many issues, and in the first version it does'nt make real sense. Who wrote that?
It compiles, but it has runtime errors and doesn't run till end.
Here is a working one (only tested with one extended axis), BUT: there seems to be an issue in the KAREL system of fanuc. At least in my test equipment the value of extended axis 1 that comes from the funtion GET_POS_TPE has nothing to do with the real value.

You can see the outputs of the WRITE statements on the User screen (MENU - 9 USER).
And one more remark: Try to write programs on your own, read the karel manuals, learn to debug programs. jm2c.
I'm out now.

Display More

thanks, everything worked

Kawazaki02 · October 10, 2020 at 2:01 PM

Hello everyone, I wrote the code. compiles. but when executing the program, it will throw an error. if you remove 47 and 75, then the program is executed well, without errors.

Code

PROGRAM TEST_KAR_10

%NOLOCKGROUP
%ENVIRONMENT REGOPE
%ALPHABETIZE
%COMMENT = 'ALL_POS_ARG'
%ENVIRONMENT TPE
%ENVIRONMENT BYNAM
%INCLUDE klevtpe

CONST

    MAX_AXS = 9    

VAR

    to_prog: STRING[25]
    open_id: INTEGER
    status: INTEGER
    
    indx_pos: INTEGER

    num_axs : INTEGER
    group_no: INTEGER
    posn_type: INTEGER
    org_xyz : XYZWPREXT
    new_xyz : XYZWPREXT

    num_pos : INTEGER

    r_val: REAL
    i_val: INTEGER
    r_flg :BOOLEAN

BEGIN

         to_prog = 'TEST_TP_1'

     OPEN_TPE (to_prog, TPE_RWACC, TPE_RDREJ, open_id, status)

             group_no = 1
             
    GET_POS_TYP (open_id, indx_pos, group_no, posn_type, num_axs, status)

        WRITE('get_pos_typ status', status,CR)
         
    FOR indx_pos = 1 TO num_pos-1 DO

        WRITE ('indx_pos', indx_pos, CR, CR)

        SELECT posn_type OF

            CASE (pt_rxyzwpr):

            GET_REG (101,r_flg, i_val, r_val, status)

        WRITE ('Got REAL value from R[101]',CR)
            
      org_xyz = GET_POS_TPE (open_id,  indx_pos, status)
             new_xyz = org_xyz
             new_xyz.x = org_xyz.x + i_val
             new_xyz.y = org_xyz.y + 0
            new_xyz.z = org_xyz.z + 0
            new_xyz.w = org_xyz.w + 0
            new_xyz.p = org_xyz.p + 0
            new_xyz.r = org_xyz.r + 0
            new_xyz.ext1 = org_xyz.ext1 + 0
            new_xyz.ext2 = org_xyz.ext2 + 0
            new_xyz.ext3 = org_xyz.ext3 - i_val

    SET_EPOS_TPE (open_id, indx_pos, new_xyz, status)

        ENDSELECT
        
    ENDFOR

    CLOSE_TPE (open_id, status)
    
END TEST_KAR_10

Display More

Nation · October 10, 2020 at 2:43 PM

Delete your .pc and the .vr file it leaves behind from the controller, then recompile. The file will complie, but fail to load because there is a difference in declared varibles in the .vr file.

Kawazaki02 · October 10, 2020 at 2:57 PM

Quote from Nation

Delete your .pc and the .vr file it leaves behind from the controller, then recompile. The file will complie, but fail to load because there is a difference in declared varibles in the .vr file.

tried it, didn't help ))

hermann · October 10, 2020 at 3:12 PM

Once again the program is not correct.

Writing programs doesn't mean to shuffle program statements found somewhere in the documentation or the internet, and hope that it will work.

You should put the 'get_pos_typ' into the loop, otherwise you can leave it out, and assume for all position that the type is pt_rxyzwpr.

1. means in line 46 there is a unitialized variable, looking into the code shows that the variable 'num_pos' is not initialized before using it.

2. This is a problem of the compiler, if the program that you want to compile is selected on the virtual controller, he fails. Select a different program on the controller an compile again.

Kawazaki02 · October 10, 2020 at 3:38 PM

Thank you for your comment. I'm just learning to program in KAREL so far, so don't judge too three. I'll try to loop the program, unsubscribe about the results =)

I just need a little support from knowledgeable people to learn from experienced )

hermann · October 10, 2020 at 4:49 PM

Yes it is hard stuff to learn programming, it is hard stuff to learn programming a robot, but it is harder stuff to learn programming by programming a robot.

And the next level is to learn programming on a fanuc robot with karel , that will be a pain in the ass, because the debugging possiblities aren't that good.

Good luck .

As always I recommend to learn programming on a personal computer with a common programming language like C, Pascal, Basic, and then switch to a robot, and learn the robot specific things.

KAREL programming FANUC

Advertising from our partners

How to see your Job Posting (search or recruit) here in Robot-Forum.com

Similar Threads

How do I know Karel is installed?

Dynamic control of FANUC Robot in Run-Time

Fanuc Code Verses Epson or ABB

Utility of KAREL Programming?

Converting a p-code in Karel function

Fanuc Virtual Environment

ABB RAPID Veteran, a few question about FANUC KAREL

Karel Program for RJ2 controller

Karel Translator Directives

HELP WITH FANUC R2000ib 165 F

Tags

Users Viewing This Thread