KUKA get actual axis joint values and compare it to the desire ones

kokkes · Aug 20th 2019

Hello to everyone,

I have been working with KUKA robots for the past 6 months and i must admit that the forum has helped me a lot on a number of issues. Thank you for this initiative!

The KUKA system software i have been working with is the 8.3 version.

For our application, we have a number of subprograms (around 200) that will be executed in External mode and controlled through a PLC and we would like to check before each subprogram execution, that the robot is in a know and well defined position (preferably check the joint values; suggestions on position values are welcome) and more specifically in the last point of the previously executed subprogram.

Our thinking for doing this is to create another subprogram, where the desired axis joint values (A1 to A6) will be manually entered as an input and the subprogram will make a comparison of current joint values with the desired ones (tolerance of +-0.2 degrees per axis). In case there is a deviation greater of 0.2 degrees in each one of the axis, a message will be displayed to the operator through the HMI.

In attachment you may find the subprogram we have been working on.

Is there another way to deal with this issue?

How can we acquire the actual joint values from the robot that rests on a specific position and compare them with the desired ones?

Any help or advise on how to resolve this issue is more than welcome and appreciated.

Thank you in advance,

Kostas

Fubini · Aug 21st 2019

You could use the $in_home signals. These are connected to the home positions in $config.dat. You can alter those to your desired positions.

Fubini

kokkes · Aug 21st 2019

Thanks for the prompt response, but it seems that the $in_home signals are only 5! I need approximately 200

**SkyeFire** · Aug 21st 2019

Something I wrote a long time ago, and kept around in my toolbox.

Basically, you'll need to create your own 'home' positions of E6AXIS, and an E6AXIS variable that contains the +/- tolerance for each axis. Then send both variables to this function.

If the difference between E6AXIS variable you send, and the robot's actual position, is less than the tolerance variable for all axes, the function will return a True. Otherwise, False.

Code

GLOBAL DEFFCT BOOL NearAxis(FI_aPose :IN, FI_aLimit :IN)
;FOLD EXECUTABLE
DECL E6AXIS FI_aPose, FI_aLimit
DECL BOOL _bInTolerance, _bContinue, _bSuccess, _bPreviousFail, _bPassFail
DECL INT  _nHandle, _nSoftKey
_bPreviousFail = FALSE
_bContinue = FALSE
_bSuccess = FALSE
_bPassFail = STRCLEAR (ErrMsgPar [1].PAR_TXT [])
_bInTolerance = TRUE ; init
WAIT FOR TRUE ; break advance run pointer


E6AxisNull (aAxisDelta) ; init
aAxisDelta.A1 = (ABS(FI_aPose.A1 - $AXIS_ACT_MES.A1))
aAxisDelta.A2 = (ABS(FI_aPose.A2 - $AXIS_ACT_MES.A2))
aAxisDelta.A3 = (ABS(FI_aPose.A3 - $AXIS_ACT_MES.A3))
aAxisDelta.A4 = (ABS(FI_aPose.A4 - $AXIS_ACT_MES.A4))
aAxisDelta.A5 = (ABS(FI_aPose.A5 - $AXIS_ACT_MES.A5))
aAxisDelta.A6 = (ABS(FI_aPose.A6 - $AXIS_ACT_MES.A6))
aAxisDelta.E1 = (ABS(FI_aPose.E1 - $AXIS_ACT_MES.E1))
aAxisDelta.E2 = (ABS(FI_aPose.E2 - $AXIS_ACT_MES.E2))
aAxisDelta.E3 = (ABS(FI_aPose.E3 - $AXIS_ACT_MES.E3))
aAxisDelta.E4 = (ABS(FI_aPose.E4 - $AXIS_ACT_MES.E4))
aAxisDelta.E5 = (ABS(FI_aPose.E5 - $AXIS_ACT_MES.E5))
aAxisDelta.E6 = (ABS(FI_aPose.E6 - $AXIS_ACT_MES.E6))


_bInTolerance = (_bInTolerance AND ((aAxisDelta.A1 < FI_aLimit.A1) OR (FI_aLimit.A1 < 0))) ; A1 dimension test
IF ((NOT _bInTolerance) EXOR _bPreviousFail) THEN
_bPreviousFail = TRUE
ErrMsgPar [1].PAR_TXT[] = "A1"
ENDIF
_bInTolerance = (_bInTolerance AND ((aAxisDelta.A2 < FI_aLimit.A2) OR (FI_aLimit.A2 < 0))) ; A2 dimension test
IF ((NOT _bInTolerance) EXOR _bPreviousFail) THEN
_bPreviousFail = TRUE
ErrMsgPar [1].PAR_TXT[] = "A2"
ENDIF
_bInTolerance = (_bInTolerance AND ((aAxisDelta.A3 < FI_aLimit.A3) OR (FI_aLimit.A3 < 0))) ; A3 dimension test
IF ((NOT _bInTolerance) EXOR _bPreviousFail) THEN
_bPreviousFail = TRUE
ErrMsgPar [1].PAR_TXT[] = "A3"
ENDIF
_bInTolerance = (_bInTolerance AND ((aAxisDelta.A4 < FI_aLimit.A4) OR (FI_aLimit.A4 < 0))) ; A4 dimension test
IF ((NOT _bInTolerance) EXOR _bPreviousFail) THEN
_bPreviousFail = TRUE
ErrMsgPar [1].PAR_TXT[] = "A4"
ENDIF
_bInTolerance = (_bInTolerance AND ((aAxisDelta.A5 < FI_aLimit.A5) OR (FI_aLimit.A5 < 0))) ; A5 dimension test
IF ((NOT _bInTolerance) EXOR _bPreviousFail) THEN
_bPreviousFail = TRUE
ErrMsgPar [1].PAR_TXT[] = "A5"
ENDIF
_bInTolerance = (_bInTolerance AND ((aAxisDelta.A6 < FI_aLimit.A6) OR (FI_aLimit.A6 < 0))) ; A6 dimension test
IF ((NOT _bInTolerance) EXOR _bPreviousFail) THEN
_bPreviousFail = TRUE
ErrMsgPar [1].PAR_TXT[] = "A6"
ENDIF
_bInTolerance = (_bInTolerance AND ((aAxisDelta.E1 < FI_aLimit.E1) OR (FI_aLimit.E1 < 0))) ; E1 dimension test
IF ((NOT _bInTolerance) EXOR _bPreviousFail) THEN
_bPreviousFail = TRUE
ErrMsgPar [1].PAR_TXT[] = "E1"
ENDIF
_bInTolerance = (_bInTolerance AND ((aAxisDelta.E2 < FI_aLimit.E2) OR (FI_aLimit.E2 < 0))) ; E2 dimension test
IF ((NOT _bInTolerance) EXOR _bPreviousFail) THEN
_bPreviousFail = TRUE
ErrMsgPar [1].PAR_TXT[] = "E2"
ENDIF
_bInTolerance = (_bInTolerance AND ((aAxisDelta.E3 < FI_aLimit.E3) OR (FI_aLimit.E3 < 0))) ; E3 dimension test
IF ((NOT _bInTolerance) EXOR _bPreviousFail) THEN
_bPreviousFail = TRUE
ErrMsgPar [1].PAR_TXT[] = "E3"
ENDIF
_bInTolerance = (_bInTolerance AND ((aAxisDelta.E4 < FI_aLimit.E4) OR (FI_aLimit.E4 < 0))) ; E4 dimension test
IF ((NOT _bInTolerance) EXOR _bPreviousFail) THEN
_bPreviousFail = TRUE
ErrMsgPar [1].PAR_TXT[] = "E4"
ENDIF
_bInTolerance = (_bInTolerance AND ((aAxisDelta.E5 < FI_aLimit.E5) OR (FI_aLimit.E5 < 0))) ; E5 dimension test
IF ((NOT _bInTolerance) EXOR _bPreviousFail) THEN
_bPreviousFail = TRUE
ErrMsgPar [1].PAR_TXT[] = "E5"
ENDIF
_bInTolerance = (_bInTolerance AND ((aAxisDelta.E6 < FI_aLimit.E6) OR (FI_aLimit.E6 < 0))) ; E6 dimension test
IF ((NOT _bInTolerance) EXOR _bPreviousFail) THEN
_bPreviousFail = TRUE
ErrMsgPar [1].PAR_TXT[] = "E6"
ENDIF
;  REPEAT
;    IF NOT _bInTolerance THEN
;      ErrModule = 9 ; Trajectory module
;     _nHandle = DlgMsg (NearCartesianErrMsg)
;      WAIT SEC 0.5
;      DlgMsgWait (_nHandle, _nSoftKey)
;      SWITCH _nSoftKey
;      CASE IgnoreSK
;        _bSuccess = TRUE
;        _bContinue = TRUE
;        _bInTolerance  = TRUE
;      DEFAULT
;        _bSuccess = FALSE
;        _bContinue = FALSE
;      ENDSWITCH
;    ELSE
;      _bSuccess = TRUE
;      _bContinue = TRUE
;    ENDIF
;  UNTIL _bContinue
RETURN _bInTolerance
;ENDFOLD EXECUTABLE
ENDFCT

Display More

kokkes · Aug 21st 2019

Thanks SkyeFire for sharing these information!

I will give it a look and try to figure it out.

Thanks a lot

**SkyeFire** · Aug 22nd 2019

Whoops -- that code won't run as-is. It depends on another function (E6AxisNull) that I keep in my standard library, although all it really does is receive an E6AXIS variable as a :OUT argument and sets all the values to 0.

And the aAxisDelta variable was declared in a .DAT file for logging and VarCor reasons. Ditto for the ErrMsgPar variable.

Setting an axis in the FI_aLimit variable to a negative value tells the function to unconditionally "pass" that axis's test -- basically, it's a "don't test this axis" flag.

This code might be better -- it's more "portable":

Code

GLOBAL DEFFCT E6AXIS E6AxisDeltaABS(FI_aPose1 :IN, FI_aPose2 :IN)
;FOLD HEADER
; Similar to E6AxisDelta, but ABS's the delta values
;ENDFOLD (HEADER)
;FOLD DECLARATIONS
DECL E6AXIS FI_aPose1
DECL E6AXIS FI_aPose2
DECL E6AXIS _aDelta
; ENDFOLD (DECLARATIONS)
;FOLD EXECUTABLE
E6AxisNull (_aDelta) ; set to 0s
ON_ERROR_PROCEED
_aDelta.A1 = ABS(FI_aPose1.A1 - FI_aPose2.A1)
ON_ERROR_PROCEED
_aDelta.A2 = ABS(FI_aPose1.A2 - FI_aPose2.A2)
ON_ERROR_PROCEED
_aDelta.A3 = ABS(FI_aPose1.A3 - FI_aPose2.A3)
ON_ERROR_PROCEED
_aDelta.A4 = ABS(FI_aPose1.A4 - FI_aPose2.A4)
ON_ERROR_PROCEED
_aDelta.A5 = ABS(FI_aPose1.A5 - FI_aPose2.A5)
ON_ERROR_PROCEED
_aDelta.A6 = ABS(FI_aPose1.A6 - FI_aPose2.A6)
ON_ERROR_PROCEED
_aDelta.E1 = ABS(FI_aPose1.E1 - FI_aPose2.E1)
ON_ERROR_PROCEED
_aDelta.E2 = ABS(FI_aPose1.E2 - FI_aPose2.E2)
ON_ERROR_PROCEED
_aDelta.E3 = ABS(FI_aPose1.E3 - FI_aPose2.E3)
ON_ERROR_PROCEED
_aDelta.E4 = ABS(FI_aPose1.E4 - FI_aPose2.E4)
ON_ERROR_PROCEED
_aDelta.E5 = ABS(FI_aPose1.E5 - FI_aPose2.E5)
ON_ERROR_PROCEED
_aDelta.E6 = ABS(FI_aPose1.E6 - FI_aPose2.E6)
RETURN _aDelta
;ENDFOLD (EXECUTABLE)
ENDFCT
GLOBAL DEFFCT BOOL AxisInTolerance(FI_aPose1 :IN, FI_aPose2 :IN, FI_aTolerance :IN)
;FOLD HEADER
; Accepts two E6AXIS poses, and an E6Axis Tolerance value
; If deltas between *all* Axes of the two poses are less than Tolerance,
;returns True.
; Only the Absolute values are evaluated -- +/- is ignored
;ENDFOLD (HEADER)
;FOLD DECLARATIONS
DECL E6AXIS FI_aPose1
DECL E6AXIS FI_aPose2
DECL E6AXIS FI_aTolerance
DECL E6AXIS _aDelta
DECL BOOL _bInTolerance
; ENDFOLD (DECLARATIONS)
;FOLD EXECUTABLE
; get ABS of Pose1.x - Pose2.x
_aDelta = E6AxisDeltaABS(FI_aPose1, FI_aPose2)


_bInTolerance = TRUE ; init
_bInTolerance = _bInTolerance AND (_aDelta.A1 <= FI_aTolerance.A1)
_bInTolerance = _bInTolerance AND (_aDelta.A2 <= FI_aTolerance.A2)
_bInTolerance = _bInTolerance AND (_aDelta.A3 <= FI_aTolerance.A3)
_bInTolerance = _bInTolerance AND (_aDelta.A4 <= FI_aTolerance.A4)
_bInTolerance = _bInTolerance AND (_aDelta.A5 <= FI_aTolerance.A5)
_bInTolerance = _bInTolerance AND (_aDelta.A6 <= FI_aTolerance.A6)
_bInTolerance = _bInTolerance AND (_aDelta.E1 <= FI_aTolerance.E1)
_bInTolerance = _bInTolerance AND (_aDelta.E2 <= FI_aTolerance.E2)
_bInTolerance = _bInTolerance AND (_aDelta.E3 <= FI_aTolerance.E3)
_bInTolerance = _bInTolerance AND (_aDelta.E4 <= FI_aTolerance.E4)
_bInTolerance = _bInTolerance AND (_aDelta.E5 <= FI_aTolerance.E5)
_bInTolerance = _bInTolerance AND (_aDelta.E6 <= FI_aTolerance.E6)


RETURN _bInTolerance
;ENDFOLD (EXECUTABLE)
ENDFCT

Display More

**panic mode** · Aug 23rd 2019

As SkyeFire already showed, the best way is to make function.

but... normally only HOME and HOME1-HOME5 are axis specific.

most of points are Cartesian, specially if using ILF to create points.

kokkes · Aug 26th 2019

Thank you for the updates!

They are much appreciated

KUKA get actual axis joint values and compare it to the desire ones

Advertising from our partners

How to see your Job Posting (search or recruit) here in Robot-Forum.com

Robotics Technician - Detroit/Ann Arbor area - Radwell International

Share

Tags