Program from manual not working

[size=2]1. Read pinned topic READ FIRST It will tell you key manuals and resources (and how and where to post) as well as what to share before asking for help [/size]
[font=verdana, arial, helvetica, sans-serif][size=2]2. When referring to other resources- be specific. What manual exactly [/size][/font]
[font=verdana, arial, helvetica, sans-serif][size=2]3. First motion must be PTP... a COMPLETE ptp. It must set initial pose of all axes. Your robot seem to have at least one external axis but you only initialize some of parameters for main axes (robot axes). [/size][/font]

[size=2]
DEF test()
DECL INT J

FOR J=1 to 6
$VEL_AXIS[J]=100 ; init speed for robot axes A1..A6
$ACC_AXIS[J]=100 ; init accel for robot axes

$VEL_EXTAX[J]=100 ; init speed for external axes E1..E6
$ACC_EXTAX[J]=100 ; init accel for external axes
ENDFOR

; specify anything else that may be useful
;$BASE = $nullframe ; world coordinate system
;$TOOL = $nullframe ; use flange as TCP
;$IPO_MODE = #BASE ; base is reference (stationary) coordinate system
;$APO = {CPTP 100, CDIS 100}

; First command must be a complete PTP
; for example move ALL axes to their present positions
; they will not really move but at least BCO (SAK) will be done:
PTP $AXIS_ACT

; and NOW that BCO/SAK is done, we can play....
; we can move SOME of axes if we like
PTP {A1 0,A2 -90,A3 90,A4 0,A5 0,A6 0}

FOR J=1 to 5
PTP {A1 45}
PTP {A2 -70,A3 50}
PTP {A4 0}
PTP {A1 0 , A2 -90, A3 90}
ENDFOR

PTP {A1 0,A2 -90,A3 90,A4 0,A5 0,A6 0}
END
[/size]

you are still not being specific. what EXACTLY is meant by "movements are not continuously possible"? i can interpret that in several ways and don't have time to pursue every option. did you read READ FIRST topic?

Quote from Bombastino

Hello Team,
I am very new in Kuka Robot use and I want to understand programming from the base. So with a VKRC2 Controller and many VW specials I wrote this program as .src . On running it will stop at the PTP command with the comment Axesspeed not programed E1. This I dont understand .
Could someone can give me the base of working with the manual and this comment!

&ACCESS RV
&REL 4
&PARAM TPVW_VERSION = 5.4.13
DEF vorgabe1( )
INT J
$VEL_AXIS[1]= 100
$VEL_AXIS[2]= 100
$VEL_AXIS[3]= 100
$VEL_AXIS[4]= 100
$VEL_AXIS[5]= 100
$VEL_AXIS[6]= 100

$ACC_AXIS[1]=100
$ACC_AXIS[2]=100
$ACC_AXIS[3]=100
$ACC_AXIS[4]=100
$ACC_AXIS[5]=100
$ACC_AXIS[6]=100
PTP {A1 0,A2 -90,A3 90,A4 0,A5 0,A6 0}

FOR J=1 to 5
PTP {A1 45}
PTP {A2 -70,A3 50}
PTP {A1 0 , A2 -90, A3 90}
ENDFOR

PTP {A1 0,A2 -90,A3 90,A4 0,A5 0,A6 0}
END

Maybe I must have another manual?
Christoph
Thank you

Display More

If You are trying to run regular KRL inside a VKRC (VW KUKA), things coud be gone strange.

VKRC doesn't run KRL natively, unless the program is inside VW_USER folder. But VW_USER isn't intended to be used to run user programs. Only VW libraries.

What manual You are using? KSS or VSS?

VKRC programs are written in a KRL dialect called VKRL.

You can insert KRL commands in a VKRC program, and the controller will understand that.

But, if by any reason You need to edit this program, when you close it, compiler will wipe any instruction that is consider non-compliant with VKRL.