Robot communication

Hi,

There are several communication methods for you, but you should check that what options you have bought.

1, Siemens PLC can communicate with your robot through TCP/IP, but your robot should have User Socket MSG option;
2, If your robot has a PROFINET I/O option, you can also communicate with Siemens PLC;
3, If your robot has Ethernet IP option and PLC has a Ethernet IP gateway module, it is possible to communicate through Ethernet IP.

Hope that helps.

Hi, Janusz
First, Open your backup file and find orderfil.dat, then u can see a bunch of (1A05B-2600-Rxxx....), google the Rxxx or search it in Summary.DG one by one then u know all your options.
Second, u could search this forum about socket message examples, like:

PROGRAM test_server
%STACKSIZE = 4000
%NOLOCKGROUP
%NOPAUSE=ERROR+COMMAND+TPENABLE
%ENVIRONMENT uif
%ENVIRONMENT sysdef
%ENVIRONMENT memo
%ENVIRONMENT kclop
%ENVIRONMENT bynam
%ENVIRONMENT fdev
%ENVIRONMENT flbt
%INCLUDE klevccdf
%INCLUDE klevkeys
%INCLUDE klevkmsk
-------------------------------------------------------------------------------
VAR
file_var : FILE
tmp_int : INTEGER
tmp_int1 : INTEGER
tmp_str : STRING[128]
tmp_str1 : STRING[128]
STATUS : INTEGER
entry : INTEGER
-------------------------------------------------------------------------------
BEGIN
SET_FILE_ATR(file_var, ATR_IA)
-- set the server port before doing a connect
SET_VAR(entry, '*SYSTEM*','$HOSTS_CFG[3].$SERVER_PORT',59002,STATUS)
WRITE('Connecting..',CR)
MSG_CONNECT('S3:',STATUS)
WRITE(' CONNECT STATUS = ',STATUS,CR)
IF STATUS = 0 THEN
-- Open S3:
   WRITE ('Opening',CR)
--   FOR tmp_int1 = 1 TO 20 DO
      OPEN FILE file_var ('rw','S3:')
      STATUS = IO_STATUS(file_var)
      WRITE (STATUS,CR)
      IF STATUS = 0 THEN
-- write an integer
             WRITE('Reading',CR)
-- Read 10 bytes
              BYTES_AHEAD(file_var, entry, STATUS)
              READ file_var (tmp_str::10)
              WRITE('receive:',tmp_str,CR )
              WRITE('send:')
              WRITE  file_var ('hello world')

       CLOSE FILE file_var
ENDIF
--ENDFOR
WRITE('Disconnecting..',CR)
MSG_DISCO('S3:',STATUS)
WRITE('Done.',CR)
ENDIF
END test_server

PROGRAM test_client
%STACKSIZE = 4000
%NOLOCKGROUP
%NOPAUSE=ERROR+COMMAND+TPENABLE
%ENVIRONMENT uif
%ENVIRONMENT sysdef
%ENVIRONMENT memo
%ENVIRONMENT kclop
%ENVIRONMENT bynam
%ENVIRONMENT fdev
%ENVIRONMENT flbt
%INCLUDE klevccdf
%INCLUDE klevkeys
%INCLUDE klevkmsk
-------------------------------------------------------------------------------
VAR
file_var : FILE
tmp_int : INTEGER
tmp_str : STRING[128]
STATUS : INTEGER
entry : INTEGER
loop1 : BOOLEAN
--------------------------------------------------------
BEGIN
SET_FILE_ATR(file_var, ATR_IA)
SET_VAR(entry, '*SYSTEM*','$HOSTC_CFG[1].$SERVER_PORT',59002,STATUS)
-- Connect the tag
WRITE('Connecting..',CR)
MSG_CONNECT('C1:',STATUS)
WRITE(' CONNECT STATUS = ',STATUS,CR)
loop1 = TRUE
IF STATUS = 0 THEN
WHILE loop1 = TRUE DO
WRITE('Opening FILE..',CR)
OPEN FILE file_var('rw','C1:')
STATUS = IO_STATUS(file_var)
IF STATUS = 0 THEN
        tmp_str = 'hello world'
       WRITE file_var(tmp_str::10)
       WRITE('send:',CR)
       READ file_var(tmp_str::12)
     WRITE('receive:',tmp_str,CR)  
     WRITE('Closed FILE',CR)
     CLOSE FILE file_var
ELSE
      WRITE('ERROR Opening FILE',CR)
      loop1 = FALSE
ENDIF
ENDWHILE
WRITE('Disconnecting..',CR)
MSG_DISCO('C1:',STATUS)
WRITE('Done.',CR)
ENDIF
END test_client

Please check your robot whether there is a R648 option in your order file, you can make a AoA backup where you can find this file.

Yes, if you select the first way, you should create your own socket using karel, you can refer to the example above.

Hi Janusz, do you want the FANUC robot to be a Device on your profinet network? You can integrate the FANUC robot controller into TIA portal and configure I/O in that manner as you're used to (including DCS safety signals as an F-device on the Profinet network). As far as I know, this is possible with the R30iB-Plus cabinets (A/B/Mate/Compact) - each has a different hardware approach. The cabinet can be configured as an I-device or I-controller depending on if you have a PLC that you want to act as the master or not.

I have a 100+ page powerpoint from FANUC on this topic and the contact info for the senior engineer at FANUC working on this product if you want to contact me in a PM.

Step1, Set your robot and your PLC in the same IP segment.
Step2, Select PLC as a client, then the robot as a server, it is also ok if you want to swap the two.
Step3, In the MENU-SETUP-Host Comm, you can find that you can configure a client or server in the list, select one, and fill in the IP address of your PLC. In you karel code like above, you can find the following line.
MSG_CONNECT('S3:',STATUS) S3 indicates Server 3.
MSG_CONNECT('C1:',STATUS) C1 indicates Client 1.
Step4, Input your code and build it in your RobotGuid, it will generate a *.pc for you, you can load this file in your TP.
Step5, Program your PLC in TIA for receiving and sending.

Maybe, there will be a lot of problems, but you have to figure it out by yourself.
I think you can read the manuals regarding karel and socket message first. And then, if you have problems, you can search in this forum.

Hope that helps.

If you have SNPX option you can buy a cheap HMI just for this communication.
Something like this:
https://www.plcdirect.eu/produ…ucts/product/mt8050-start
Siemens PLC communicates with HMI.
Robot using SNPX communicates with HMI.