Cannot find trigonometric functions

ashwinmudigonda · February 19, 2018 at 11:12 PM

I am trying to use basic trig functions, and I am not able to see PSIN, PCOS,... under the CALL options for programs, macros, Karel, or anything.

I don't have the "System design tool" option installed. I do see how to activate the trig functions in the manual for that module.

Are these functions available with another module. I have the Motion Interface and Motion Package add ons.

HawkME · February 20, 2018 at 1:00 AM

Fanuc robots dont allow you to use the advanced math functions without paying extra. You must purchase the Math Function option to unlock them. Then they show up under the register instructions.

Sent from my SM-G930V using Tapatalk

Nation · February 20, 2018 at 3:45 PM

I've heard it is a fairly cheap option, but if you don't want to go that route, I've had some success using Taylor expansion to approximate the trig functions.

ashwinmudigonda · February 20, 2018 at 6:55 PM

I figured that was the case, and also went ahead with a Taylor series implementation. Thanks.

rf103 · February 21, 2018 at 12:12 AM

If you have Karel you could write a few simple programs that call sin, cos and other functions for you and put the results in registers. That is basically what the trigonometric programs do.

TitusLepic · February 21, 2018 at 7:03 PM

Here is how I've done trig functions in TP (sin, cos, tan, taylor approximation of atan). None of it is elegant, but it works.

Code

/PROG  MATH_ATN
/ATTR
OWNER		= MNEDITOR;
COMMENT		= "";
PROG_SIZE	= 416;
CREATE		= DATE 16-05-05  TIME 11:24:27;
MODIFIED	= DATE 16-08-22  TIME 11:30:12;
FILE_NAME	= ATAN;
VERSION		= 0;
LINE_COUNT	= 14;
MEMORY_SIZE	= 708;
PROTECT		= READ_WRITE;
TCD:  STACK_SIZE	= 0,
      TASK_PRIORITY	= 50,
      TIME_SLICE	= 0,
      BUSY_LAMP_OFF	= 0,
      ABORT_REQUEST	= 0,
      PAUSE_REQUEST	= 0;
DEFAULT_GROUP	= *,*,*,*,*;
CONTROL_CODE	= 00000000 00000000;
/APPL
/MN
   1:  R[12:Indirect TAN]=AR[1]    ;
   2:  R[13:ATAN VALUE]=R[R[12]]    ;
   3:  CALL MATH_POW(R[13:ATAN VALUE],3) ;
   4:  R[14:ATAN TAYLOR 1]=R[55:MATH POWER RESUT]    ;
   5:  R[14:ATAN TAYLOR 1]=R[14:ATAN TAYLOR 1]/3    ;
   6:  CALL MATH_POW(R[13:ATAN VALUE],5) ;
   7:  R[15:ATAN TAYLOR 2]=R[55:MATH POWER RESUT]    ;
   8:  R[15:ATAN TAYLOR 2]=R[15:ATAN TAYLOR 2]/5    ;
   9:   ;
  10:  R[17:ATAN RESULT]=R[13:ATAN VALUE]    ;
  11:  R[17:ATAN RESULT]=R[17:ATAN RESULT]-R[14:ATAN TAYLOR 1]    ;
  12:  R[17:ATAN RESULT]=R[17:ATAN RESULT]+R[15:ATAN TAYLOR 2]    ;
  13:  R[17:ATAN RESULT]=R[17:ATAN RESULT]*180/3.1416    ;
  14:  R[R[12]]=R[17:ATAN RESULT]    ;
/POS
/END


/PROG  MATH_COS
/ATTR
OWNER		= MNEDITOR;
COMMENT		= "";
PROG_SIZE	= 254;
CREATE		= DATE 17-12-05  TIME 10:10:08;
MODIFIED	= DATE 17-12-05  TIME 10:10:12;
FILE_NAME	= MATH_SIN;
VERSION		= 0;
LINE_COUNT	= 6;
MEMORY_SIZE	= 570;
PROTECT		= READ_WRITE;
TCD:  STACK_SIZE	= 0,
      TASK_PRIORITY	= 50,
      TIME_SLICE	= 0,
      BUSY_LAMP_OFF	= 0,
      ABORT_REQUEST	= 0,
      PAUSE_REQUEST	= 0;
DEFAULT_GROUP	= 1,*,*,*,*;
CONTROL_CODE	= 00000000 00000000;
/APPL
/MN
   1:  PR[26:TRIG]=LPOS    ;
   2:  PR[26:TRIG]=PR[26:TRIG]-PR[26:TRIG]    ;
   3:  PR[26,6:TRIG]=AR[1]    ;
   4:  UFRAME[9]=PR[26:TRIG] ;
   5:  PR[26:TRIG]=UFRAME[9] ;
   6:  R[26:COS]=PR[26,1:TRIG]    ;
/POS
/END


/PROG  MATH_POW
/ATTR
OWNER		= MNEDITOR;
COMMENT		= "Math Power Funcn";
PROG_SIZE	= 246;
CREATE		= DATE 16-05-04  TIME 08:44:15;
MODIFIED	= DATE 16-05-04  TIME 11:23:08;
FILE_NAME	= ;
VERSION		= 0;
LINE_COUNT	= 8;
MEMORY_SIZE	= 686;
PROTECT		= READ_WRITE;
TCD:  STACK_SIZE	= 0,
      TASK_PRIORITY	= 50,
      TIME_SLICE	= 0,
      BUSY_LAMP_OFF	= 0,
      ABORT_REQUEST	= 0,
      PAUSE_REQUEST	= 0;
DEFAULT_GROUP	= *,*,*,*,*;
CONTROL_CODE	= 00000000 00000000;
/MN
   1:  R[53:MATH POWER BASE]=AR[1]    ;
   2:  R[54:MATH POWER EXP]=AR[2]    ;
   3:  R[55:MATH POWER RESUT]=R[53:MATH POWER BASE]    ;
   4:  R[56:MATH POWER COUNT]=1    ;
   5:  LBL[1] ;
   6:  R[55:MATH POWER RESUT]=R[55:MATH POWER RESUT]*
    :  R[53:MATH POWER BASE]    ;
   7:  R[56:MATH POWER COUNT]=R[56:MATH POWER COUNT]+1    ;
   8:  IF R[56:MATH POWER COUNT]<R[54:MATH POWER EXP],JMP LBL[1] ;
/POS
/END


/PROG  MATH_SIN
/ATTR
OWNER		= MNEDITOR;
COMMENT		= "";
PROG_SIZE	= 212;
CREATE		= DATE 17-12-05  TIME 10:04:00;
MODIFIED	= DATE 17-12-05  TIME 10:12:12;
FILE_NAME	= ;
VERSION		= 0;
LINE_COUNT	= 6;
MEMORY_SIZE	= 528;
PROTECT		= READ_WRITE;
TCD:  STACK_SIZE	= 0,
      TASK_PRIORITY	= 50,
      TIME_SLICE	= 0,
      BUSY_LAMP_OFF	= 0,
      ABORT_REQUEST	= 0,
      PAUSE_REQUEST	= 0;
DEFAULT_GROUP	= 1,*,*,*,*;
CONTROL_CODE	= 00000000 00000000;
/MN
   1:  PR[26:TRIG]=LPOS    ;
   2:  PR[26:TRIG]=PR[26:TRIG]-PR[26:TRIG]    ;
   3:  PR[26,6:TRIG]=AR[1]    ;
   4:  UFRAME[9]=PR[26:TRIG] ;
   5:  PR[26:TRIG]=UFRAME[9] ;
   6:  R[25:SIN]=PR[26,2:TRIG]    ;
/POS
/END


/PROG  MATH_TAN
/ATTR
OWNER		= MNEDITOR;
COMMENT		= "";
PROG_SIZE	= 182;
CREATE		= DATE 17-12-05  TIME 10:13:21;
MODIFIED	= DATE 17-12-05  TIME 10:15:10;
FILE_NAME	= ;
VERSION		= 0;
LINE_COUNT	= 3;
MEMORY_SIZE	= 526;
PROTECT		= READ_WRITE;
TCD:  STACK_SIZE	= 0,
      TASK_PRIORITY	= 50,
      TIME_SLICE	= 0,
      BUSY_LAMP_OFF	= 0,
      ABORT_REQUEST	= 0,
      PAUSE_REQUEST	= 0;
DEFAULT_GROUP	= 1,*,*,*,*;
CONTROL_CODE	= 00000000 00000000;
/MN
   1:  CALL MATH_SIN(AR[1]) ;
   2:  CALL MATH_COS(AR[1]) ;
   3:  R[27:TAN]=R[25:SIN]/R[26:COS]    ;
/POS
/END

Display More

Cannot find trigonometric functions

Advertising from our partners

How to see your Job Posting (search or recruit) here in Robot-Forum.com